Adding metadata

35 files changed, 897 insertions, 21 deletions

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index deec88ae6b49..f9ce3604bd13 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1 +1,2 @@
 DIST astroid-3.0.2.gh.tar.gz 461786 BLAKE2B d005fe36e6d7dc4bfc7388f1d4ac52c4602f7c18accfacbeb55545b382fe5e16ef7cedd493aef5413b57a5ac872807b8d9857fc02a7b4053edd54780814f64e8 SHA512 88fa6ff9c66f5224113001c4911cbe2f3055b990c5d0b3ac206166575d7fd5b7fae99fa67a655703d7868ee8c47841ece8b2c2d44712b1fdaf39fa26f786815f
+DIST astroid-3.0.3.gh.tar.gz 461982 BLAKE2B a41d29b69dc0b0098a449ca0d93934edb5cad56017776971f0982b97b742472bcc731b409c582ca8ab9daabf20d9a84b950a70b08d830bc42ef90ba922fafbcd SHA512 88164dcefa4136c53450d228128c0bb317218fbceb39c4889a7e313691fa0f0b04fed5fb5e25c6a46883d432f11289a4cd3306757a109d314e62580db0261289
diff --git a/dev-python/astroid/astroid-3.0.3.ebuild b/dev-python/astroid/astroid-3.0.3.ebuild
new file mode 100644
index 000000000000..9e5f0a15cecc
--- /dev/null
+++ b/dev-python/astroid/astroid-3.0.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/regex[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# pydantic-2?
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		# requires urllib3 with bundled six (skipped with urllib3>=2)
+		tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+		# requires pip, looks fragile
+		tests/test_manager.py::IsolatedAstroidManagerTest::test_no_user_warning
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/blake3/Manifest b/dev-python/blake3/Manifest
index 3bd3a67cbbf1..4e454bb165cf 100644
--- a/dev-python/blake3/Manifest
+++ b/dev-python/blake3/Manifest
@@ -5,6 +5,7 @@ DIST bitflags-1.3.2.crate 23021 BLAKE2B eb990bb27b2bdeb66fd7212ce582cb36e1c616de
 DIST blake3-1.5.0.crate 168914 BLAKE2B 72d1851f3cbe5c996570f5cf0cb4ab8c4215ac0e95a6b930dd64ff650333a8745ad1b63a2f988227d66a096cafc59777aeec8e63c05a22d666c1bdd58acaa320 SHA512 39c4d3d370bede96b3f4e37c44514dddfd1ef91d178116e1556eb8f3e2687b705e2320f842e600e59229198aeffff4ab1de34eaf59e8a3c039003f13d0f08aab
 DIST blake3-py-0.3.4.gh.tar.gz 114853 BLAKE2B 0aee132e7446e2e1727e50b9d50454645798d5f5daafdd5844a2e47f560bfbd23633707c4803b2d8583c3402041dac9115f09648dba251e4a3b570cfb76ea6fb SHA512 9b55249833c0066cc977b292d8e586175a5b3eb14b1619f2b402be960a65b189c8fdee9c5e7b3cfb44af2e588227c9864be1a95d486ad705a182253cae533c27
 DIST blake3-py-0.4.0.gh.tar.gz 115883 BLAKE2B 3c2a2148b2eec9a0c24081b445c36c909d2dd80ba19a8afc487622cb16aa599b67feab5ab441f87b6df894f351ce560f17e55df10bf91033a4cff5bc84d70069 SHA512 6ac25d62acb85e3923d4e26651e2dba849452306ccaa4bdbf075b9a8886061c3827f13ab300f77c496a2c83343d1f714e5940772780e7c1bbcb66d5096092114
+DIST blake3-py-0.4.1.gh.tar.gz 116080 BLAKE2B 9fd2db2a573182ec4bab9d6e37750f4afff9b200e2bb9fe4c26e6bfde328ad2aab162d2adcadc312f3e007ddca19d92c73e058466caddf6c7aa7fc10b553f51a SHA512 e166d2d6ac52dac4158e7b494e83398afd692cb8b93951809338f8da26d337506e3ce2bf37528da6960cfab9b6e3f229a2b5e845dd9a83b35028249113869112
 DIST cc-1.0.83.crate 68343 BLAKE2B 33245b33fa845ea2f36da36e3830ec835f937e4319865b357ee9d5ea29a0f9f8392eadb38bf1d95e3c15ed201e561acaa87aedcef744f8db3dabff87a96c7f02 SHA512 742a248c3a7547bb220a0b9c97b67a831fab9b4ac21daa08c85a3966b9fe576088def33e16132fcabec9a2828a6fc437088bb045bfc98b2cea829df6742565a7
 DIST cfg-if-1.0.0.crate 7934 BLAKE2B e99a5589c11d79d77a4537b34ce0a45d37b981c123b79b807cea836c89fc3926d693458893baca2882448d3d44e3f64e06141f6d916b748daa10b8cc1ae16d1b SHA512 0fb16a8882fd30e86b62c5143b1cb18ab564e84e75bd1f28fd12f24ffdc4a42e0d2e012a99abb606c12efe3c11061ff5bf8e24ab053e550ae083f7d90f6576ff
 DIST constant_time_eq-0.3.0.crate 11369 BLAKE2B a6fb4ad3146b26bb3e18458938e65133431df129963041465291b38a69ba2b53ffcc849f455e67a65a5291803591b350afe4ad4996f1c4cb76c18a987b5b3ee2 SHA512 77bf6817c521daa45c0df7721418b4aa367531adde46b1db97316d52ffb46fc4ee2d3e6f62ff91ca6292db5e1d3e040f0f5287c3936f12a595b2c8c5928bf5e6
diff --git a/dev-python/blake3/blake3-0.4.1.ebuild b/dev-python/blake3/blake3-0.4.1.ebuild
new file mode 100644
index 000000000000..8e376e96b74c
--- /dev/null
+++ b/dev-python/blake3/blake3-0.4.1.ebuild
@@ -0,0 +1,134 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CARGO_OPTIONAL=1
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+CRATES="
+	arrayref@0.3.7
+	arrayvec@0.7.4
+	autocfg@1.1.0
+	bitflags@1.3.2
+	blake3@1.5.0
+	cc@1.0.83
+	cfg-if@1.0.0
+	constant_time_eq@0.3.0
+	crossbeam-deque@0.8.5
+	crossbeam-epoch@0.9.18
+	crossbeam-utils@0.8.19
+	either@1.9.0
+	heck@0.4.1
+	hex@0.4.3
+	indoc@2.0.4
+	libc@0.2.153
+	lock_api@0.4.11
+	memmap2@0.7.1
+	memoffset@0.9.0
+	once_cell@1.19.0
+	parking_lot@0.12.1
+	parking_lot_core@0.9.9
+	proc-macro2@1.0.78
+	pyo3-build-config@0.20.2
+	pyo3-ffi@0.20.2
+	pyo3-macros-backend@0.20.2
+	pyo3-macros@0.20.2
+	pyo3@0.20.2
+	quote@1.0.35
+	rayon-core@1.12.1
+	rayon@1.8.1
+	redox_syscall@0.4.1
+	scopeguard@1.2.0
+	smallvec@1.13.1
+	syn@2.0.48
+	target-lexicon@0.12.13
+	unicode-ident@1.0.12
+	unindent@0.2.3
+	windows-targets@0.48.5
+	windows_aarch64_gnullvm@0.48.5
+	windows_aarch64_msvc@0.48.5
+	windows_i686_gnu@0.48.5
+	windows_i686_msvc@0.48.5
+	windows_x86_64_gnu@0.48.5
+	windows_x86_64_gnullvm@0.48.5
+	windows_x86_64_msvc@0.48.5
+"
+
+inherit cargo distutils-r1
+
+MY_P=blake3-py-${PV}
+DESCRIPTION="Python bindings for the BLAKE3 cryptographic hash function"
+HOMEPAGE="
+	https://github.com/oconnor663/blake3-py/
+	https://pypi.org/project/blake3/
+"
+SRC_URI="
+	https://github.com/oconnor663/blake3-py/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	rust? (
+		${CARGO_CRATE_URIS}
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="
+	|| ( CC0-1.0 Apache-2.0 )
+	rust? (
+"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0-with-LLVM-exceptions BSD-2 MIT Unicode-DFS-2016
+	|| ( Apache-2.0 CC0-1.0 )
+"
+LICENSE+="
+	)
+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+rust"
+
+BDEPEND="
+	rust? (
+		${RUST_DEPEND}
+		dev-util/maturin[${PYTHON_USEDEP}]
+	)
+	!rust? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/blake3/blake3.*.so"
+
+distutils_enable_tests pytest
+
+src_unpack() {
+	cargo_src_unpack
+}
+
+src_prepare() {
+	# sed the package name and version to improve compatibility
+	sed -e 's:blake3_experimental_c:blake3:' \
+		-e "s:0[.]0[.]1:${PV}:" \
+		-i c_impl/setup.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	local DISTUTILS_USE_PEP517=$(usex rust maturin setuptools)
+
+	if ! use rust; then
+		cd c_impl || die
+	fi
+	distutils-r1_python_compile
+	if ! use rust; then
+		cd - >/dev/null || die
+	fi
+}
diff --git a/dev-python/fsspec/Manifest b/dev-python/fsspec/Manifest
index b94f9a2ba2cc..beb901808bef 100644
--- a/dev-python/fsspec/Manifest
+++ b/dev-python/fsspec/Manifest
@@ -1,2 +1,3 @@
 DIST filesystem_spec-2023.10.0.gh.tar.gz 404845 BLAKE2B 6c8cf801664c9fc848cb55660db1725c90facf534d58e49f604b2051d1b6a78d13d8f083282071beb7ab3dcb8d75f6d52fe24ce744c5cf1808b4ae3cb673998d SHA512 cb449052208516930c73dbe1de7c495d252677a3d3d85267836224d79c1b8cf9449ebdba8287f6f6206d5a8e631a99cd81c2fb62b82288a626a202876a45139c
 DIST filesystem_spec-2023.12.2.gh.tar.gz 409321 BLAKE2B f074d8d3277a954bebc29bca663d142763a6b9f13edb43286b1f59aff125c9eec0ae18cfa44b99a35daca7a9bf89a627c9abe57cbebe713ac494ca98f61899eb SHA512 654ff72b9c5ca648d4a4b469b4f3706b3200f023e26b657e3200dee301469da6f67c93fcfaa82edae7c7b074fe77715d0093269a38ee68416cf8491203bde5cb
+DIST filesystem_spec-2024.2.0.gh.tar.gz 424600 BLAKE2B 548f77229dd936437cbafcd4e8df2a5c25e6244ba5c95553cb84eabbb6d8c2aa16313896b4aecbb6c921d01f84c6c5517b13a2cf1552cac0fa29da8034873143 SHA512 ca8c7c448984ecd9b128608f2c028cf32baf3cda3f22addde80c3bef5c1e5644e010b739fb5d28dc951151fdafb4006def080e8c2c769179b1d145ad6e2f9370
diff --git a/dev-python/fsspec/fsspec-2024.2.0.ebuild b/dev-python/fsspec/fsspec-2024.2.0.ebuild
new file mode 100644
index 000000000000..87cd0f83ac9b
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2024.2.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=filesystem_spec-${PV}
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="
+	https://github.com/fsspec/filesystem_spec/
+	https://pypi.org/project/fsspec/
+"
+SRC_URI="
+	https://github.com/fsspec/filesystem_spec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+# Note: this package is not xdist-friendly
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+EPYTEST_DESELECT=(
+	fsspec/tests/test_spec.py::test_find
+	# requires s3fs
+	fsspec/implementations/tests/test_local.py::test_urlpath_inference_errors
+	fsspec/tests/test_core.py::test_mismatch
+	# requires pyarrow, fastparquet
+	fsspec/implementations/tests/test_reference.py::test_df_single
+	fsspec/implementations/tests/test_reference.py::test_df_multi
+)
+
+EPYTEST_IGNORE=(
+	# sftp and smb require server started via docker
+	fsspec/implementations/tests/test_dbfs.py
+	fsspec/implementations/tests/test_sftp.py
+	fsspec/implementations/tests/test_smb.py
+	# unhappy about dev-python/fuse-python (?)
+	fsspec/tests/test_fuse.py
+)
diff --git a/dev-python/gpep517/gpep517-15.ebuild b/dev-python/gpep517/gpep517-15.ebuild
index b2f9dc453038..2752656dc955 100644
--- a/dev-python/gpep517/gpep517-15.ebuild
+++ b/dev-python/gpep517/gpep517-15.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2023 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # please keep this ebuild at EAPI 7 -- sys-apps/portage dep
@@ -32,6 +32,11 @@ RDEPEND="
 
 distutils_enable_tests pytest
 
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o tmp_path_retention_policy=all
+}
+
 python_install() {
 	python_domodule gpep517
 	python_newscript - gpep517 <<-EOF
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 949f10798eb0..31f0a75cca5b 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -4,3 +4,4 @@ DIST hypothesis-6.97.1.gh.tar.gz 9423481 BLAKE2B 6a52bf6a970bf8056284baaa21aa63f
 DIST hypothesis-6.97.3.gh.tar.gz 9424749 BLAKE2B 4d7f2b1f9e37593006c5be8e66918a2e20cf611664f0399bca32e97d2a5ef036a0e64c9c45bdbd8bdd385bb8e07a6a0d7a396135db826a59d223c9e87baab483 SHA512 2cf6f92f6fbd244e44b4e02415ea983d15113b2a89d4222e8fb215b555f87442d7c4ed1b6da33f1ac9189df274a6a61d222a0d4e78cbb418f6c80f8ba4591051
 DIST hypothesis-6.97.4.gh.tar.gz 9425209 BLAKE2B 7e6065fc988f5853f1da3df712d32e7449ba6336af9caf6732a391ed4dc9fbc5da7fcf834cb068ad57a106f451cd61141417d9b79048c8e746a6b4550bad7f65 SHA512 a4aaa4fc3d753401620e234e27b0b269fa2bddd039345df0463600c6cbd5b38f6a09a9a01c322e08ecf7c9f27c881501403f2ec083497c26d512e5ffd41b7afc
 DIST hypothesis-6.97.5.gh.tar.gz 9426065 BLAKE2B 2aec769268af7392f71c0ec7d12defad4962bd56597cb68ca0edfa81dbf28ef7d865b26086b75ee03287c82a0b2c0273a55bd6872b188728595fe74198130dd6 SHA512 d9f2adc51ef3b7fc331d3dca1b69a9464a2bc73298747f3732b8b4621237284ac60a50b927b57a047a155e0d94a3ee2974bbef2c9cf9112080e9098fba3cfc7f
+DIST hypothesis-6.98.1.gh.tar.gz 9438665 BLAKE2B c2529e19b8ac039db334a51b33e0552f4acb92ae49b6bde5e26913b4ba7781e82a5ba4cfd7fba2a3ed5442d1bd8f0c2b2d7878ba86eff1276e590a412856811d SHA512 aae7f7c03af4667b0d9993a1b911076fe4d1ce7d752295a7e9f712da4d33b1fd34e51d5e0cc11c4ac4c00e7f8fa9ac4574d0594e1a82ea67aa3e5a4e98ed1b71
diff --git a/dev-python/hypothesis/hypothesis-6.98.1.ebuild b/dev-python/hypothesis/hypothesis-6.98.1.ebuild
new file mode 100644
index 000000000000..1f7054962839
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.98.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" --dist=worksteal \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/jupyterlab-lsp/Manifest b/dev-python/jupyterlab-lsp/Manifest
index 4dd670c93133..2437175a7dc4 100644
--- a/dev-python/jupyterlab-lsp/Manifest
+++ b/dev-python/jupyterlab-lsp/Manifest
@@ -1,2 +1,3 @@
 DIST jupyterlab-lsp-5.0.1.tar.gz 755832 BLAKE2B d8082aaf9c1219fedeebd6a717b81f08a7bba2a8618dc99b2ecf9a6d28c4e6cbf34b711c4fae4a847675ea05d2dc7acd0c812a772e9d51f37f563d088398c088 SHA512 7fef1ab7309978aa9185afdc895a7adefc72210842228d055150b231b70980e772abf166762820971f653cf0f5abd65e9bdfe3a206c4aed99b4586fec684399e
 DIST jupyterlab-lsp-5.0.2.tar.gz 757169 BLAKE2B e1d7b26805264c570275e021ac2c4af688c70c428b0966c4f6fb75f890be55b1543602f93e6565f6ade485bec6b3d5f8d680c73c07b3f069f25990a6ad633b2b SHA512 f2826cd4d940855814d2f7cb7a07eaf4c9fb8d8440fd1f27b381804ee2c892f00461d49166e90fb8f7aa3eae64aa873973369ba56a1e484f349aab7c05d0dbc6
+DIST jupyterlab-lsp-5.0.3.tar.gz 757263 BLAKE2B df2a3a1a1cb0a9a9345f151ae5c510056ca26868353d457b7aa4b6405041f0b4e55afba09019722a1f37592b46b1a8e53b40c8f595215f74cea29a598b029648 SHA512 20d5a3e33fbab8b5e47a10f23b12cf7e91ca5d4ac9020345e3cc973a391643cd380ff182f1109a387a7ebcced6becd1b7847a888829cb30be1f4ed536177575f
diff --git a/dev-python/jupyterlab-lsp/jupyterlab-lsp-5.0.3.ebuild b/dev-python/jupyterlab-lsp/jupyterlab-lsp-5.0.3.ebuild
new file mode 100644
index 000000000000..bbb385f0de0c
--- /dev/null
+++ b/dev-python/jupyterlab-lsp/jupyterlab-lsp-5.0.3.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Coding assistance for JupyterLab with Language Server Protocol"
+HOMEPAGE="
+	https://github.com/jupyter-lsp/jupyterlab-lsp/
+	https://pypi.org/project/jupyterlab-lsp/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jupyterlab-4.0.0[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-2.0.0[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
deleted file mode 100644
index 637368d2f237..000000000000
--- a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
+++ /dev/null
@@ -1,13 +0,0 @@
-Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
-
---- a/setup.py
-+++ b/setup.py
-@@ -18,7 +18,7 @@ setup(
-     author_email='michal.danilak@gmail.com',
-     url='https://github.com/Mimino666/langdetect',
-     keywords='language detection library',
--    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
-+    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
-     include_package_data=True,
-     install_requires=['six'],
-     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index 630fe63c6f53..c09b7356f549 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2024 Gentoo Authors
+# Copyright 2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,6 +19,4 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
-PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
-
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 736a1167c898..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,6 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
- <origin>gentoo-guru-overlay</origin>
+ <maintainer type="person">
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/linkify-it-py/Manifest b/dev-python/linkify-it-py/Manifest
index 1581c8d3feb6..c44f9f3a3ef4 100644
--- a/dev-python/linkify-it-py/Manifest
+++ b/dev-python/linkify-it-py/Manifest
@@ -1 +1,2 @@
 DIST linkify-it-py-2.0.2.gh.tar.gz 76692 BLAKE2B b702ed78b002eac4f902dccf595150734de820b8e09e92d8339951ecbb348640d21605b7627f0ba208426f755c68f809dc6c82ec7c1b5eb450240ca4600d5355 SHA512 141002cf5c2b2760f242eb1d294833437e0df0caf671103ddb6099a083e2b6e8f20f35508b164b14206ceae2ffecb5361aa4d839152f7c52f3cfa83e905f12a7
+DIST linkify-it-py-2.0.3.gh.tar.gz 76727 BLAKE2B df0d2c8f31a9715c6eadd1f8fb295990b5ed82b8f49231071f8220045d9b64ec21098477d43a74afa21592b2a345357654a23df38636e852a767c62443580e34 SHA512 6621533246a42f3b13fb7dd9f1366cadb0e3c291bcb92fd899bc6389cb9f7904ababf4b5dbae51a561a4f50f8a20597badf03c82653ae8db75d9a5a484bc1229
diff --git a/dev-python/linkify-it-py/linkify-it-py-2.0.3.ebuild b/dev-python/linkify-it-py/linkify-it-py-2.0.3.ebuild
new file mode 100644
index 000000000000..a82566911e4a
--- /dev/null
+++ b/dev-python/linkify-it-py/linkify-it-py-2.0.3.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Links recognition library with full unicode support"
+HOMEPAGE="
+	https://github.com/tsutsu3/linkify-it-py/
+	https://pypi.org/project/linkify-it-py/
+"
+# no tests in sdist, as of 2.0.1
+SRC_URI="
+	https://github.com/tsutsu3/linkify-it-py/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/uc-micro-py[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/ml_dtypes/Manifest b/dev-python/ml-dtypes/Manifest
index bc543760e578..bc543760e578 100644
--- a/dev-python/ml_dtypes/Manifest
+++ b/dev-python/ml-dtypes/Manifest
diff --git a/dev-python/ml_dtypes/metadata.xml b/dev-python/ml-dtypes/metadata.xml
index 72e10dd03722..72e10dd03722 100644
--- a/dev-python/ml_dtypes/metadata.xml
+++ b/dev-python/ml-dtypes/metadata.xml
diff --git a/dev-python/ml_dtypes/ml_dtypes-0.2.0.ebuild b/dev-python/ml-dtypes/ml-dtypes-0.2.0.ebuild
index 38b917e61628..a24be89b616a 100644
--- a/dev-python/ml_dtypes/ml_dtypes-0.2.0.ebuild
+++ b/dev-python/ml-dtypes/ml-dtypes-0.2.0.ebuild
@@ -3,6 +3,7 @@
 
 EAPI=8
 
+PNGH="${PN/-/_}" # pypi is ml-dtypes, github is ml_dtypes
 PYTHON_COMPAT=( python3_{8,9,10,11,12} )
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=setuptools
@@ -13,7 +14,7 @@ EIGEN_CommitId="7bf2968fed5f246c0589e1111004cb420fcd7c71"
 DESCRIPTION="A stand-alone implementation of several NumPy dtype extensions"
 HOMEPAGE="https://github.com/jax-ml/ml_dtypes"
 SRC_URI="
-	https://github.com/jax-ml/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/jax-ml/${PNGH}/archive/refs/tags/v${PV}.tar.gz -> ${PNGH}-${PV}.gh.tar.gz
 	https://gitlab.com/libeigen/eigen/-/archive/${EIGEN_CommitId}/eigen-${EIGEN_CommitId}.tar.bz2
 "
 
diff --git a/dev-python/ml_dtypes/ml_dtypes-0.3.2.ebuild b/dev-python/ml-dtypes/ml-dtypes-0.3.2.ebuild
index 38b917e61628..a24be89b616a 100644
--- a/dev-python/ml_dtypes/ml_dtypes-0.3.2.ebuild
+++ b/dev-python/ml-dtypes/ml-dtypes-0.3.2.ebuild
@@ -3,6 +3,7 @@
 
 EAPI=8
 
+PNGH="${PN/-/_}" # pypi is ml-dtypes, github is ml_dtypes
 PYTHON_COMPAT=( python3_{8,9,10,11,12} )
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=setuptools
@@ -13,7 +14,7 @@ EIGEN_CommitId="7bf2968fed5f246c0589e1111004cb420fcd7c71"
 DESCRIPTION="A stand-alone implementation of several NumPy dtype extensions"
 HOMEPAGE="https://github.com/jax-ml/ml_dtypes"
 SRC_URI="
-	https://github.com/jax-ml/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/jax-ml/${PNGH}/archive/refs/tags/v${PV}.tar.gz -> ${PNGH}-${PV}.gh.tar.gz
 	https://gitlab.com/libeigen/eigen/-/archive/${EIGEN_CommitId}/eigen-${EIGEN_CommitId}.tar.bz2
 "
 
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index d75deddf087b..2627de08e799 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -8,3 +8,4 @@ DIST moto-4.2.7.tar.gz 4756973 BLAKE2B 2ab27952abd6faaa2bbe7b6565f5d5403ea4e2c5c
 DIST moto-4.2.8.tar.gz 4769361 BLAKE2B 2e7d6a7cac04655aa9f05af463e57689c0fc2b67cec27644fdf7fd658d988d33f311e43323599a0f91325f7b4e61630a3066d3fda2a15b0c0ca50e6a7cf34e22 SHA512 5a40d44ad46083b6e7c8753e8986316a5beb5b352e7e7b0eefe2b3f3ed2d760f0745f835b6e7d6b2d7b039db0b6f2fad095f047795d2d08093257fa68db1ceee
 DIST moto-4.2.9.tar.gz 4775687 BLAKE2B af626a18c9487c08172813ddf2f1112d4bba80dbb64bf8deaf63079a6d4c12464e70d7c99d5a65fd1018f9f3a08bd0b12183e04a549fdfe580942086d49b9e21 SHA512 4cca0bdbe106faa84fa3893eb1dc2b2972a85c98ca718a10fd08a06757e1634954c5576c82b66d88c431a51b989cfedb2a52e6455d718330d4a5dd6e95a90225
 DIST moto-5.0.0.tar.gz 4925737 BLAKE2B 45d60d1c7a53d9743cd4f3ac74a2108f9a6916dea09abb067111acbddf2ba5bb69e6ba354cdeb6be88876e4b8a8270876cfd4dab95339e948bf7cfb6e417e7d2 SHA512 44705d9b5aa5b373687fb34cae1d047b67b312bb788414f7b6c19b3f1e06fdf8fa69e88ae5df56bcc2ef0a74809211e0372fadb555ad57f50f313587d7dedb83
+DIST moto-5.0.1.tar.gz 4933500 BLAKE2B 730bb8ca2db3e1a82d88cff0362d4be750bf138df0e52a04c18d707d965b093c5e07b400789b0bd8874e68ea7c8159911c0d84b3f535ac1da8d18e786e1f44af SHA512 0f72e6c07ab3c24ba70a309517498e77ed809970121ae5b63c249e4f73ebefa7787bbcfcacc310b0ae566d81c2dd8d0e0d767cba3bbbefb72e2620f1f2ea45fa
diff --git a/dev-python/moto/moto-5.0.1.ebuild b/dev-python/moto/moto-5.0.1.ebuild
new file mode 100644
index 000000000000..f5be3a7de576
--- /dev/null
+++ b/dev-python/moto/moto-5.0.1.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.15.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		# broken code (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_awslambda/test_lambda_layers_invoked.py::test_invoke_local_lambda_layers
+		tests/test_batch/test_batch_jobs.py::test_cancel_pending_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_running_job
+		tests/test_batch/test_batch_jobs.py::test_container_overrides
+		tests/test_batch/test_batch_jobs.py::test_dependencies
+		tests/test_batch/test_batch_jobs.py::test_failed_dependencies
+		tests/test_batch/test_batch_jobs.py::test_failed_job
+		tests/test_batch/test_batch_jobs.py::test_submit_job_array_size
+		tests/test_batch/test_batch_jobs.py::test_terminate_job
+		tests/test_batch/test_batch_jobs.py::test_terminate_nonexisting_job
+		tests/test_cloudformation/test_cloudformation_custom_resources.py::test_create_custom_lambda_resource__verify_cfnresponse_failed
+
+		tests/test_cloudformation/test_cloudformation_stack_integration.py::test_lambda_function
+		tests/test_core/test_docker.py::test_docker_is_running_and_available
+		tests/test_core/test_request_passthrough.py
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_aws_and_http_requests
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_http_requests
+		tests/test_events/test_events_lambdatriggers_integration.py::test_creating_bucket__invokes_lambda
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events0-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events1-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events3-ObjectCreated:Put]"
+		# TODO
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_queue
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_fifo_queue
+		# require py_partiql_parser
+		tests/test_s3/test_s3_select.py
+		tests/test_dynamodb/test_dynamodb_statements.py
+		# broken by new urllib3
+		tests/test_moto_api/recorder/test_recorder.py::TestRecorder::test_s3_upload_data
+		tests/test_moto_api/recorder/test_recorder.py::TestRecorder::test_s3_upload_file_using_requests
+		tests/test_s3/test_s3.py::test_upload_from_file_to_presigned_url
+		tests/test_s3/test_s3.py::test_put_chunked_with_v4_signature_in_body
+		tests/test_s3/test_s3.py::test_presigned_put_url_with_approved_headers
+		tests/test_s3/test_s3.py::test_presigned_put_url_with_custom_headers
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x TZ=UTC
+
+	local serial_tests=(
+		# these tests set up credentials that are needed by the tests below
+		tests/test_core/test_importorder.py
+		# these tests apparently rely on some other test setting credentials
+		# up for them, so they need to be run separately, after the above
+		tests/test_awslambda_simple/test_lambda_simple.py::test_run_function{,_no_log}
+		tests/test_dynamodb/exceptions/test_dynamodb_exceptions.py
+		tests/test_dynamodb/exceptions/test_dynamodb_transactions.py::test_transaction_with_empty_key
+		tests/test_dynamodb/test_dynamodb.py::test_transact_write_items_failure__return_item
+		tests/test_dynamodb/test_dynamodb.py::test_transact_write_items_put_conditional_expressions
+		tests/test_dynamodb/test_dynamodb_update_expressions.py::test_update_different_map_elements_in_single_request
+		tests/test_events/test_events.py::test_start_replay_send_to_log_group
+		tests/test_lakeformation/test_resource_tags_integration.py
+		tests/test_redshiftdata
+		tests/test_resourcegroupstaggingapi/test_server.py::test_resourcegroupstaggingapi_list
+		tests/test_s3/test_s3.py::test_delete_bucket_cors
+		tests/test_s3/test_s3.py::test_delete_objects_percent_encoded
+		tests/test_s3/test_s3.py::test_delete_versioned_bucket_returns_metadata
+		tests/test_s3/test_s3_copyobject.py::test_copy_key_boto3_with_args
+		tests/test_s3/test_s3_copyobject.py::test_copy_key_boto3_with_args__using_multipart
+		tests/test_s3/test_s3_file_handles.py::TestS3FileHandleClosuresUsingMocks
+		tests/test_s3/test_s3_list_object_versions.py
+		tests/test_s3/test_s3_tagging.py
+		tests/test_s3control/test_s3control_access_points.py::test_delete_access_point
+		tests/test_utilities/test_threaded_server.py::TestThreadedMotoServer::test_server_can_handle_multiple_services
+		tests/test_utilities/test_threaded_server.py::TestThreadedMotoServer::test_server_is_reachable
+	)
+
+	EPYTEST_XDIST= epytest "${serial_tests[@]}"
+
+	EPYTEST_DESELECT+=( "${serial_tests[@]}" )
+	epytest -m 'not network'
+}
diff --git a/dev-python/packaging/packaging-23.2-r1.ebuild b/dev-python/packaging/packaging-23.2-r1.ebuild
new file mode 100644
index 000000000000..68334c5acaea
--- /dev/null
+++ b/dev-python/packaging/packaging-23.2-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Core utilities for Python packages"
+HOMEPAGE="
+	https://github.com/pypa/packaging/
+	https://pypi.org/project/packaging/
+"
+
+SLOT="0"
+LICENSE="|| ( Apache-2.0 BSD-2 )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	!<dev-python/setuptools-67
+"
+DEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest --capture=no
+}
diff --git a/dev-python/path/Manifest b/dev-python/path/Manifest
index 0737215de8da..3f372545aca1 100644
--- a/dev-python/path/Manifest
+++ b/dev-python/path/Manifest
@@ -1 +1,2 @@
+DIST path-16.10.0.tar.gz 49271 BLAKE2B 36762e0b50d74b07db14ca01c6d94577f24b36c007eda58de4b63197cd91f869efbdc5ac1ceb270f1fc5e5a07c4c87f6cabd10cbac5fac74681f73451a3f73e1 SHA512 a5dfa964f5ffd4c2aa27733716b67437f02fd6dedc8c574bb87a9a3ac64eb60d27c3a05217aa4859293ebd96bdd17cdb1a04ea21c6ad35b7b22f05725826c057
 DIST path-16.9.0.tar.gz 48850 BLAKE2B 0c5edc6538cb22543dd810a535840a235b66c51415284f00338bd1e84e63847d09235e55dd3d40a71f3b02f54d18cbbf4fa1e5a0356798cee3383666a26a441c SHA512 2d4c8e3923bc712c7901328a0406ce05c6c157664dfacb5a563a1b214ce561215398b31494865c99a77ed09c3ef63bb04a36d57a60e7c0e3dea05b1dacfdecf7
diff --git a/dev-python/path/path-16.10.0.ebuild b/dev-python/path/path-16.10.0.ebuild
new file mode 100644
index 000000000000..b9e1eec7bd99
--- /dev/null
+++ b/dev-python/path/path-16.10.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A module wrapper for os.path"
+HOMEPAGE="
+	https://github.com/jaraco/path/
+	https://pypi.org/project/path/
+"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# unreliable, not really meaningful for end users
+	test_path.py::TestPerformance
+)
diff --git a/dev-python/plette/Manifest b/dev-python/plette/Manifest
index 10d00efa515c..bca984057c24 100644
--- a/dev-python/plette/Manifest
+++ b/dev-python/plette/Manifest
@@ -1 +1,2 @@
 DIST plette-0.4.4.gh.tar.gz 36359 BLAKE2B dc630b9e98db9a8f6047fe0bb31c2ab29d695745b59d457c9cac218922c0d578a474f80ddc419364fb8ef92c5952c5cea33ee571cce2d698015466edb738885a SHA512 c4342ce040966730d2eba638c718c1db9340051baa89238b99e64cf8ef734fe448f0aaeae224e9f6b51c9e38458e9caeb2c8d6abbd5db76249529aaee90ed5c0
+DIST plette-1.0.0.gh.tar.gz 54297 BLAKE2B 7ade29df8bfc20d5c98f5f3290acea2f5e884f71b13c0950373f41240de54f3ea672d16c0557fef2e1be25aef0da68d4a7449ebea2f206d92901d7f11f6cc2bb SHA512 72a3f270f76dbf32cb418628f1b24046111a46633603b07fd44fd4ed50d946653afaec070bce8e67a1ecff3ec8607f2476d3b25760c76726218873898bef97ed
diff --git a/dev-python/plette/plette-1.0.0.ebuild b/dev-python/plette/plette-1.0.0.ebuild
new file mode 100644
index 000000000000..86fb823637a0
--- /dev/null
+++ b/dev-python/plette/plette-1.0.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Structured Pipfile and Pipfile.lock models"
+HOMEPAGE="
+	https://github.com/sarugaku/plette/
+	https://pypi.org/project/plette/
+"
+# pypi tarballs are missing test data
+SRC_URI="
+	https://github.com/sarugaku/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	dev-python/cerberus[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/psycopg/Manifest b/dev-python/psycopg/Manifest
index c05d2de94f1a..fa4f90338f52 100644
--- a/dev-python/psycopg/Manifest
+++ b/dev-python/psycopg/Manifest
@@ -1,4 +1,5 @@
 DIST psycopg-3.1.16.gh.tar.gz 502759 BLAKE2B 6c0b912c2a93425ddbed842a437e042b58ec859b3cf163aa7cd45a0db21084fea58945b40028e0491460b7d4da6648cfc361e1434d43ec7ab71af91f1a0c4c86 SHA512 d6cfcc848c089ef79c817bf271bcbad7078cdacacef4ab26e882fdbe55c90ac12644e7ee0af22f4cf1fa759033e94ee54c812bca7b517b84cda77276557e8ca8
 DIST psycopg-3.1.17.gh.tar.gz 503318 BLAKE2B 43c0c5ef0be20c9415c7dbe3b2ff242f30341d055bcf00ff4f9d9926c5c95df3bf10735e338c37f9e805562544637e75fd9edd5dbf71d67b42d04eea19e5c82e SHA512 d9f0ce05be71d67dbd7d1abad548befcdc229b53de93d5c08a52cae287d6f5293de6ede380c9ffc25ffa4d935782e90e9b04783f1c4c1fb88cb9ffd7016aabd5
+DIST psycopg-3.1.18.gh.tar.gz 503513 BLAKE2B 35e5e4cb4e5355189b387fd17e1b51d4baf08f130cc5418f9f3cb58d6baf097953b4f6a7df31579a1d87e5269e110c4476d865fe12416e2fe62abbb52e0c141c SHA512 1e27eec49f3ae99f1fec68816dff3974aa9b1f526df45ccca295c7c6703cc309ca4f8f65d7e3450b628906a938c65f8cbd1a1f3cb6a41b6e51dc5e220985af39
 DIST psycopg2-2.9.4.tar.gz 384017 BLAKE2B 4bc0afcc890c8a257c1ccd5c6e4e5301857a80f8b1428aa46c1473c9e18f5d2914a2e592c13336b06106217bb334d9b0321835bdd123f1627cbeb29dedf97bf7 SHA512 259088e42e0ab0d8a1a0ccf04f5e560f32c6179b4a0a0059e91bcf269baa8f4b0f1f949c332c640a2438c927a29b2c144078a861f8e18ba9c764da7c93c73b8d
 DIST psycopg2-2.9.9.tar.gz 384926 BLAKE2B 8418fca1329703cedfc86be74d85cae5133a0604bb8a21fa43e5359a46626d38ef227d0cd8fbbeb497e2db517a469d7f3e86b74ef9163617a547e999073a6b4c SHA512 a691fd09762221e854861dedce37b05e5354e0701feea470a6d5046960056ef02a8c9ecfa751adeba485271ea7d5834643b7d3a3c3f3270087f5ed9c68509f5f
diff --git a/dev-python/psycopg/psycopg-3.1.18.ebuild b/dev-python/psycopg/psycopg-3.1.18.ebuild
new file mode 100644
index 000000000000..4a1ad4e4210d
--- /dev/null
+++ b/dev-python/psycopg/psycopg-3.1.18.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="PostgreSQL database adapter for Python"
+HOMEPAGE="
+	https://www.psycopg.org/psycopg3/
+	https://github.com/psycopg/psycopg/
+	https://pypi.org/project/psycopg/
+"
+SRC_URI="
+	https://github.com/psycopg/psycopg/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="+native-extensions"
+
+DEPEND="
+	native-extensions? (
+		>=dev-db/postgresql-8.1:=
+	)
+	!native-extensions? (
+		>=dev-db/postgresql-8.1:*
+	)
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/typing-extensions-4.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/tomli[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-db/postgresql-8.1[server]
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/dnspython[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	# Python code + ctypes backend
+	cd psycopg || die
+	distutils-r1_python_compile
+
+	# optional C backend
+	if use native-extensions && [[ ${EPYTHON} != pypy3 ]]; then
+		local DISTUTILS_USE_PEP517=standalone
+		cd ../psycopg_c || die
+		distutils-r1_python_compile
+	fi
+	cd .. || die
+}
+
+src_test() {
+	rm -r psycopg{,_c} || die
+
+	initdb -D "${T}"/pgsql || die
+	# TODO: random port
+	pg_ctl -w -D "${T}"/pgsql start \
+		-o "-h '' -k '${T}'" || die
+	createdb -h "${T}" test || die
+
+	local -x PSYCOPG_TEST_DSN="host=${T} dbname=test"
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${T}"/pgsql stop || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# tests for the psycopg_pool package
+		tests/pool
+		# some broken mypy magic
+		tests/test_module.py::test_version
+		tests/test_module.py::test_version_c
+		tests/test_typing.py
+		tests/crdb/test_typing.py
+		# TODO, relying on undefined ordering in Python?
+		tests/test_dns_srv.py::test_srv
+	)
+
+	local impls=( python )
+	if use native-extensions && [[ ${EPYTHON} != pypy3 ]]; then
+		impls+=( c )
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PSYCOPG_IMPL
+	for PSYCOPG_IMPL in "${impls[@]}"; do
+		einfo "Testing with ${PSYCOPG_IMPL} implementation ..."
+		# leak and timing tests are fragile whereas slow tests are slow
+		epytest -p anyio -k "not leak" \
+			-m "not timing and not slow and not flakey"
+	done
+}
diff --git a/dev-python/pyroute2/pyroute2-0.7.10-r1.ebuild b/dev-python/pyroute2/pyroute2-0.7.10-r1.ebuild
new file mode 100644
index 000000000000..577cdae65ab5
--- /dev/null
+++ b/dev-python/pyroute2/pyroute2-0.7.10-r1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A pure Python netlink and Linux network configuration library"
+HOMEPAGE="
+	https://github.com/svinota/pyroute2/
+	https://pypi.org/project/pyroute2/
+"
+
+LICENSE="|| ( GPL-2+ Apache-2.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+# tests need root access
+RESTRICT="test"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/starlette/Manifest b/dev-python/starlette/Manifest
index af5444fcbaed..b7dc06a3b5e1 100644
--- a/dev-python/starlette/Manifest
+++ b/dev-python/starlette/Manifest
@@ -1,3 +1,4 @@
 DIST starlette-0.35.1.gh.tar.gz 2842796 BLAKE2B 1ea63f30d65103754559700eb2db699b3d03ce1dfc78081e7d2b9a680839dd0a453059d858e8b1390da2779ba755d5074033c53b5392ee7071fee27cc6739935 SHA512 75703c2ee23dd19e9c8bdd24a0a3d84f50486c0df0cad9609e0e08eb1fd3c61a4f56887d60018fbec4227bde2b3e12fb09decc865b8d5073bc4a1e066b6d5f69
 DIST starlette-0.36.1.gh.tar.gz 2843494 BLAKE2B 633cd664785f32423c0dfeab04b400340b5e3197f4ef07edca9fcda20954444ccfef1ff9afc62969d5b2914f2091e08946420931ee1ee22e1ab771fe02db13ec SHA512 9a990098a1faa179bcf8df64237147d59e3114b1336f491ca358ffd0016412f18323845eb5f8691aa41810fef455e97cb47ff34d9456a0e3a5be3eb6b23027bb
 DIST starlette-0.36.2.gh.tar.gz 2843707 BLAKE2B 7ec75189d7e9864fe15823692d2d264586be8772a0ff29e1d539eb15f858ef9d77ef6398e203f5c2f8a507869026fd8863931a176923f29bf11457e58cdb66fa SHA512 fedccb1db4cfe4a0dac321c843ae211e436ec5b07c0e65b663914657a9cec61a900d95dac09b6752a51defbb310a8dce30f0867574523a3c96cf33cd19b61c76
+DIST starlette-0.36.3.gh.tar.gz 2844320 BLAKE2B 74e2b7449cf18393c63a2123e7537704bcf85528d504c33dc579b7660ef13c11fe74ba4da6e680063d9849f5addddaeaa5c20cc770bf658613b56da2f7d9191d SHA512 998e8958810efbc329382d86f6084d7ed90dca68bb64c51349b2dae6740ba537db10ec68a007e95a81ab06f5df39c64d998b3e87432a8fc75da3ead0963bcc5d
diff --git a/dev-python/starlette/starlette-0.36.3.ebuild b/dev-python/starlette/starlette-0.36.3.ebuild
new file mode 100644
index 000000000000..2bc6499860f7
--- /dev/null
+++ b/dev-python/starlette/starlette-0.36.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="The little ASGI framework that shines"
+HOMEPAGE="
+	https://www.starlette.io/
+	https://github.com/encode/starlette/
+	https://pypi.org/project/starlette/
+"
+# no docs or tests in sdist, as of 0.27.0
+SRC_URI="
+	https://github.com/encode/starlette/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/python-multipart-0.0.7[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Unpackaged 'databases' dependency
+	tests/test_database.py
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/waitress/Manifest b/dev-python/waitress/Manifest
index b0f2255a11fb..67cb11d0d7f7 100644
--- a/dev-python/waitress/Manifest
+++ b/dev-python/waitress/Manifest
@@ -1 +1,2 @@
 DIST waitress-2.1.2.tar.gz 179823 BLAKE2B 0cbd172050f1da845c47b3a084cd5d7558c736c416372f22af4d4b6870ef6cd9050f4779fabaa5069b6b4783d748df98e2484eaed09da4d2cfc2d239ce15a05a SHA512 4ef487e116b34eede0f04a02ca7a78116a91664814067a8562d1cd15a4ab702e5faf4be7c122478324d017b6bb1f5315633b74405d00e900b34cc8f1a068da59
+DIST waitress-3.0.0.tar.gz 179393 BLAKE2B 266130e3f0610098c29fe11076f58c8f938439c9b80e9630b917e829b64c88d06803c9208137b220827ed1deb8e9ba2c396dfcaf8d92435ee738d580dbda6f26 SHA512 8b391eb194fce32fd78c1a20cd1afe8caf20e7e0c622e4be2b1ec7d3831cb5a607cda0637d08dcd3a55f2e8c84817abdad4636bf2ca260b12a774dcfa68b9176
diff --git a/dev-python/waitress/waitress-3.0.0.ebuild b/dev-python/waitress/waitress-3.0.0.ebuild
new file mode 100644
index 000000000000..48ad605f46fd
--- /dev/null
+++ b/dev-python/waitress/waitress-3.0.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A pure-Python WSGI server"
+HOMEPAGE="
+	https://docs.pylonsproject.org/projects/waitress/en/latest/
+	https://pypi.org/project/waitress/
+	https://github.com/Pylons/waitress/
+"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fails on some systems, https://bugs.gentoo.org/782031
+	tests/test_wasyncore.py::DispatcherWithSendTests::test_send
+)
+
+src_prepare() {
+	sed -i -e 's:--cov::' setup.cfg || die
+	distutils-r1_src_prepare
+}