Adding metadata

13 files changed, 261 insertions, 9 deletions

diff --git a/dev-python/aiofiles/aiofiles-23.2.1.ebuild b/dev-python/aiofiles/aiofiles-23.2.1.ebuild
index dfbd16e234b3..3b1451d8f036 100644
--- a/dev-python/aiofiles/aiofiles-23.2.1.ebuild
+++ b/dev-python/aiofiles/aiofiles-23.2.1.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/ensurepip-pip/Manifest b/dev-python/ensurepip-pip/Manifest
index c61343989e0b..5b9e6087348e 100644
--- a/dev-python/ensurepip-pip/Manifest
+++ b/dev-python/ensurepip-pip/Manifest
@@ -1 +1,2 @@
 DIST pip-23.3.2-py3-none-any.whl 2109393 BLAKE2B 278b9941f93951508ae2f508b1b5a9fddd4ca11fac1d5b0c2ac994f8e8457226a4e8c4501078776476e0bae56fd82b989ebaf4f5f484ffe7b0ee79789e34aca8 SHA512 a1449fe400787f73ac26cb48acaae71208a2e696f9ce4992b44e11da29646b018c2f6c27a95b12e42531236fe658e0605e20d5dfa740c43e005c01da3db802da
+DIST pip-24.0-py3-none-any.whl 2110226 BLAKE2B 6a0c8c9796cd574ef1d709de40a8530a15e50158143e332b79e5ad3edceda6ce93c5ef4df49b169062598618dcc6967c2115ac2c10b05abf345318204f1eeffc SHA512 5d7462a584105bccaa9cf376f5a8c5827ead099c813c8af7392d478a4398f373d9e8cac7bbad2db51b335411ab966b21e119b1b1234c9a7ab70c6ddfc9306da6
diff --git a/dev-python/ensurepip-pip/ensurepip-pip-24.0.ebuild b/dev-python/ensurepip-pip/ensurepip-pip-24.0.ebuild
new file mode 100644
index 000000000000..85e9351f85b0
--- /dev/null
+++ b/dev-python/ensurepip-pip/ensurepip-pip-24.0.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pypi
+
+DESCRIPTION="Shared pip wheel for ensurepip Python module"
+HOMEPAGE="https://pypi.org/project/pip/"
+SRC_URI="$(pypi_wheel_url "${PN#ensurepip-}")"
+S=${DISTDIR}
+
+LICENSE="Apache-2.0 BSD BSD-2 ISC LGPL-2.1+ MIT MPL-2.0 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	!<dev-python/ensurepip-wheels-100
+"
+
+src_install() {
+	insinto /usr/lib/python/ensurepip
+	doins "${A}"
+}
diff --git a/dev-python/mysqlclient/Manifest b/dev-python/mysqlclient/Manifest
index 94091ea67072..8e2072ac9b88 100644
--- a/dev-python/mysqlclient/Manifest
+++ b/dev-python/mysqlclient/Manifest
@@ -1 +1,2 @@
 DIST mysqlclient-2.2.1.tar.gz 89966 BLAKE2B b5098ea4afe8ba720c40eda2f0f5da043622bed51a123e225530d505edfef2f02efba477238d73f343a6cc4969bf021156e15528f05a12d905ea6231e47d65bd SHA512 3ff3823cef4662268387e5c13d006595219c5a3371201eb251d84db5eec028b32fd7b672dbdac9f4dffa906fddcfc9a5ee130e3b03e4dc0cfb060411ad75eea8
+DIST mysqlclient-2.2.3.tar.gz 90174 BLAKE2B 11626ac7cc93d70667cd105f77df5666f605fb16290f77ef485666e1f74b3aa47fdddaa2ea9f6b6196682f0c9772abe6c8557e01836362cc97ca6f0459716ae0 SHA512 72dd6fc351642adfa8148ff76da352233d83f8c11d8f8ad925b4a6e5d4c3dbe12e6a78d5cc1cd430b37d81d2a306c83bc5f262282f74a6c13e22cd09eeeeeaf3
diff --git a/dev-python/mysqlclient/mysqlclient-2.2.3.ebuild b/dev-python/mysqlclient/mysqlclient-2.2.3.ebuild
new file mode 100644
index 000000000000..ee497af9f593
--- /dev/null
+++ b/dev-python/mysqlclient/mysqlclient-2.2.3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python interface to MySQL"
+HOMEPAGE="
+	https://pypi.org/project/mysqlclient/
+	https://github.com/PyMySQL/mysqlclient/
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	dev-db/mysql-connector-c:0=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-db/mariadb[server]
+	)
+"
+
+distutils_enable_sphinx doc \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	rm -r src || die
+
+	local datadir="${T}/mysql" \
+		install_log="${T}/mysqld_install.log" \
+		pidfile="${T}/mysqld.pid" \
+		socket="${T}/mysqld.sock" \
+		log="${T}/mysqld.log"
+	einfo "Creating test MySQL instance ..."
+	if ! mysql_install_db \
+		--no-defaults \
+		--auth-root-authentication-method=normal \
+		--basedir="${EPREFIX}/usr" \
+		--datadir="${datadir}" >& "${install_log}"
+	then
+		cat "${install_log}"
+		die "Failed to create database"
+	fi
+
+	einfo "Starting test MySQL instance ..."
+	mysqld \
+		--no-defaults \
+		--character-set-server=utf8 \
+		--pid-file="${pidfile}" \
+		--socket="${socket}" \
+		--skip-networking \
+		--datadir="${datadir}" >& "${log}" &
+
+	local i timeout=10
+	einfo "Waiting for MySQL to start for up to ${timeout} seconds ..."
+	for i in seq 1 ${timeout}; do
+		[[ -S "${socket}" ]] && break
+		sleep 1
+	done
+	if [[ ! -S "${socket}" ]]; then
+		cat "${log}"
+		die "MySQL failed to start in ${timeout} seconds"
+	fi
+
+	cat > "${T}/mysql.cnf" <<- EOF
+		[MySQLdb-tests]
+		socket = ${socket}
+		user = root
+		database = test
+	EOF
+
+	distutils-r1_src_test
+
+	einfo "Stopping test MySQL instance ..."
+	pkill -F "${pidfile}" &>/dev/null
+}
+
+python_test() {
+	local -x TESTDB="${T}/mysql.cnf"
+	epytest
+}
diff --git a/dev-python/pip/Manifest b/dev-python/pip/Manifest
index a4fdc41bde0a..9932b567968a 100644
--- a/dev-python/pip/Manifest
+++ b/dev-python/pip/Manifest
@@ -1 +1,2 @@
 DIST pip-23.3.2.gh.tar.gz 9397451 BLAKE2B 65e656cf3e7c3ab48b5cfa48f105cae158068f3daee497edfb93e34887afa134b2cfea73574947ca22ec2664dd814034166301fb0f70322ca92852a68052be40 SHA512 976c6ab9959805f4d20d4bdedb4dabc95dd55f1ec78773f63f738599bbe44e766ad3a1394bee052a2c2386826d67686ad456726373345ba9e0d555fd251dff09
+DIST pip-24.0.gh.tar.gz 9398156 BLAKE2B 17a7ed9e15e9b8efa0d3e3c5586dc446958b62cf9ba52155a0d1ad97a3e212ee7a08a0e88a592718fc3d542eb8f434155a75cb98d90c008904bd8f59bd2b40b6 SHA512 0c2ecb2ecde4f155c83468d35bc4f52f37efffc16821ae7c706d035e1e8cc3709b41cb10f8140ff09205e8bbdba2c76128ad76d1cbd18401328b619228e834df
diff --git a/dev-python/pip/pip-24.0.ebuild b/dev-python/pip/pip-24.0.ebuild
new file mode 100644
index 000000000000..a1fcb393d4fd
--- /dev/null
+++ b/dev-python/pip/pip-24.0.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# please bump dev-python/ensurepip-pip along with this package!
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{8,9,10,11,12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="The PyPA recommended tool for installing Python packages"
+HOMEPAGE="
+	https://pip.pypa.io/en/stable/
+	https://pypi.org/project/pip/
+	https://github.com/pypa/pip/
+"
+SRC_URI="
+	https://github.com/pypa/pip/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+# bundled deps
+LICENSE+=" Apache-2.0 BSD BSD-2 ISC LGPL-2.1+ MPL-2.0 PSF-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/setuptools-39.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/ensurepip-setuptools
+			dev-python/ensurepip-wheel
+			dev-python/freezegun[${PYTHON_USEDEP}]
+			dev-python/pretend[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/scripttest[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+			dev-python/werkzeug[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+			test-rust? (
+				dev-python/cryptography[${PYTHON_USEDEP}]
+			)
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/pip-23.1-no-coverage.patch"
+		# https://github.com/pypa/pip/pull/12415
+		"${FILESDIR}/pip-23.3.1-no-color.patch"
+	)
+
+	distutils-r1_python_prepare_all
+
+	if use test; then
+		local wheels=(
+			"${BROOT}"/usr/lib/python/ensurepip/{setuptools,wheel}-*.whl
+		)
+		mkdir tests/data/common_wheels/ || die
+		cp "${wheels[@]}" tests/data/common_wheels/ || die
+	fi
+}
+
+python_compile_all() {
+	# 'pip completion' command embeds full $0 into completion script, which confuses
+	# 'complete' and causes QA warning when running as "${PYTHON} -m pip".
+	# This trick sets correct $0 while still calling just installed pip.
+	local pipcmd='import sys; sys.argv[0] = "pip"; __file__ = ""; from pip._internal.cli.main import main; sys.exit(main())'
+	"${EPYTHON}" -c "${pipcmd}" completion --bash > completion.bash || die
+	"${EPYTHON}" -c "${pipcmd}" completion --zsh > completion.zsh || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return 0
+	fi
+
+	local EPYTEST_DESELECT=(
+		tests/functional/test_inspect.py::test_inspect_basic
+		# Internet
+		tests/functional/test_config_settings.py::test_backend_sees_config_via_sdist
+		tests/functional/test_config_settings.py::test_config_settings_implies_pep517
+		tests/functional/test_install.py::test_double_install_fail
+		tests/functional/test_install.py::test_editable_install__local_dir_setup_requires_with_pyproject
+		tests/functional/test_install.py::test_link_hash_in_dep_fails_require_hashes
+		tests/functional/test_install_config.py::test_prompt_for_keyring_if_needed
+	)
+
+	if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/functional/test_install.py::test_install_sends_client_cert
+			tests/functional/test_install_config.py::test_do_not_prompt_for_authentication
+			tests/functional/test_install_config.py::test_prompt_for_authentication
+			tests/functional/test_install_config.py::test_prompt_for_keyring_if_needed
+		)
+	fi
+
+	case ${EPYTHON} in
+		python3.10)
+			EPYTEST_DESELECT+=(
+				# no clue why they fail
+				tests/unit/test_base_command.py::test_base_command_global_tempdir_cleanup
+				tests/unit/test_base_command.py::test_base_command_local_tempdir_cleanup
+				tests/unit/test_base_command.py::test_base_command_provides_tempdir_helpers
+			)
+			;;
+	esac
+
+	local -x PIP_DISABLE_PIP_VERSION_CHECK=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local EPYTEST_XDIST=1
+	epytest -m "not network"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS.txt docs/html/**/*.rst )
+	distutils-r1_python_install_all
+
+	newbashcomp completion.bash pip
+
+	insinto /usr/share/zsh/site-functions
+	newins completion.zsh _pip
+}
diff --git a/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3-r1.ebuild b/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3-r1.ebuild
index 92759c1877ad..964badc16f62 100644
--- a/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3-r1.ebuild
+++ b/dev-python/pytest-lazy-fixture/pytest-lazy-fixture-0.6.3-r1.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~mips ppc64 ~riscv ~s390 sparc x86"
+KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~loong ~mips ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
 	<dev-python/pytest-8[${PYTHON_USEDEP}]
diff --git a/dev-python/quart-trio/quart-trio-0.11.1.ebuild b/dev-python/quart-trio/quart-trio-0.11.1.ebuild
index 561a8af0ea85..d703f5d9c8c6 100644
--- a/dev-python/quart-trio/quart-trio-0.11.1.ebuild
+++ b/dev-python/quart-trio/quart-trio-0.11.1.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~riscv"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv"
 
 RDEPEND="
 	>=dev-python/exceptiongroup-1.0.0[${PYTHON_USEDEP}]
diff --git a/dev-python/quart/quart-0.19.4.ebuild b/dev-python/quart/quart-0.19.4.ebuild
index 5817da51ec08..4e81caaa1b99 100644
--- a/dev-python/quart/quart-0.19.4.ebuild
+++ b/dev-python/quart/quart-0.19.4.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~riscv"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv"
 
 RDEPEND="
 	dev-python/aiofiles[${PYTHON_USEDEP}]
diff --git a/dev-python/twisted/metadata.xml b/dev-python/twisted/metadata.xml
index 595e86b07132..5adaff6ee946 100644
--- a/dev-python/twisted/metadata.xml
+++ b/dev-python/twisted/metadata.xml
@@ -22,7 +22,6 @@ twisted.trial: A unit testing framework that integrates well with Twisted-based
  </upstream>
  <use>
   <flag name="conch">include Twisted SSHv2 implementation</flag>
-  <flag name="http2">include http2 support</flag>
   <flag name="serial">include serial port support</flag>
  </use>
  <origin>gentoo-staging</origin>
diff --git a/dev-python/urllib3/metadata.xml b/dev-python/urllib3/metadata.xml
index 67bd6c255e5d..cef61f226361 100644
--- a/dev-python/urllib3/metadata.xml
+++ b/dev-python/urllib3/metadata.xml
@@ -8,9 +8,6 @@
  <upstream>
   <remote-id type="cpe">cpe:/a:urllib3:urllib3</remote-id>
  </upstream>
- <use>
-  <flag name="http2">Enable HTTP/2.0 support.</flag>
- </use>
  <origin>gentoo-staging</origin>
  <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/urllib3/urllib3-2.2.0.ebuild b/dev-python/urllib3/urllib3-2.2.0.ebuild
index 284d963c339b..14440ca7eed0 100644
--- a/dev-python/urllib3/urllib3-2.2.0.ebuild
+++ b/dev-python/urllib3/urllib3-2.2.0.ebuild
@@ -27,7 +27,7 @@ SRC_URI+="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~riscv"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv"
 IUSE="brotli http2 test zstd"
 RESTRICT="!test? ( test )"