blob: 01862336005ba12c583b5283de9218794d288a35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Keep an eye on Fedora's packaging (https://src.fedoraproject.org/rpms/libcap-ng/tree/rawhide) for patches
# Same maintainer in Fedora as upstream
PYTHON_COMPAT=( python3_{11..14} )
inherit autotools dot-a flag-o-matic linux-info out-of-source-utils python-r1
DESCRIPTION="POSIX 1003.1e capabilities"
HOMEPAGE="https://people.redhat.com/sgrubb/libcap-ng/"
SRC_URI="https://github.com/stevegrubb/libcap-ng/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
IUSE="bpf deprecated python static-libs"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
bpf? (
dev-libs/libbpf:=
sys-process/audit
)
python? ( ${PYTHON_DEPS} )
"
DEPEND="
${RDEPEND}
sys-kernel/linux-headers
bpf? ( dev-util/bpftool )
"
BDEPEND="
bpf? (
llvm-core/clang[llvm_targets_BPF(-)]
virtual/pkgconfig
)
python? ( >=dev-lang/swig-2 )
"
PATCHES=(
"${FILESDIR}"/${PN}-0.9.3-audit-out-of-source-build.patch
)
pkg_pretend() {
# bug 972898
if use bpf && [[ ${MERGE_TYPE} != binary ]] ; then
if [[ ! -f /sys/kernel/btf/vmlinux ]] ; then
local err="Cannot read /sys/kernel/btf/vmlinux, which is required by bpftool.\n"
err+=" Typically this means that your kernel is missing the DEBUG_INFO_BTF option,\n"
err+=" without which BPF cannot work. Please build with USE=-bpf or reconfigure your kernel."
die "${err}"
fi
# check required kernel flags as documented at:
# https://github.com/stevegrubb/libcap-ng/blob/master/README.md
local CONFIG_CHECK="
~BPF
~BPF_SYSCALL
~BPF_EVENTS
~DEBUG_INFO_BTF
~FTRACE_SYSCALLS
~KPROBES
~KRETPROBES
~KPROBE_EVENTS
~PERF_EVENTS
~STACKTRACE
~TRACEPOINTS
~TRACING
"
linux-info_pkg_setup
fi
}
src_prepare() {
default
eautoreconf
}
src_configure() {
use sparc && replace-flags -O? -O0
# bug #960469
use static-libs && lto-guarantee-fat
local ECONF_SOURCE="${S}"
local myconf=(
$(use_enable bpf cap-audit)
$(use_enable deprecated)
$(use_enable static-libs static)
--with-capability_header="${ESYSROOT}"/usr/include/linux/capability.h
)
local pythonconf=(
--without-python3
)
# Set up python bindings build(s)
if use python ; then
setup_python_flags_configure() {
pythonconf=(
--with-python3
)
run_in_build_dir econf "${pythonconf[@]}" "${myconf[@]}"
}
python_foreach_impl setup_python_flags_configure
else
local BUILD_DIR="${WORKDIR}"/build
run_in_build_dir econf "${pythonconf[@]}" "${myconf[@]}"
fi
}
src_compile() {
if use python ; then
python_foreach_impl run_in_build_dir emake
else
local BUILD_DIR="${WORKDIR}"/build
emake -C "${BUILD_DIR}"
fi
}
src_test() {
if [[ "${EUID}" -eq 0 ]] ; then
ewarn "Skipping tests due to root permissions."
return
fi
if use python ; then
python_foreach_impl run_in_build_dir emake check
else
local BUILD_DIR="${WORKDIR}"/build
emake -C "${BUILD_DIR}" check
fi
}
src_install() {
if use python ; then
python_foreach_impl run_in_build_dir emake DESTDIR="${D}" install
else
local BUILD_DIR="${WORKDIR}"/build
emake -C "${BUILD_DIR}" DESTDIR="${D}" install
fi
# bug #960469
use static-libs && strip-lto-bytecode
find "${ED}" -name '*.la' -delete || die
}
|
