blob: 8c8f83f915317019df04d1f3261a00d2d80a0554 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit optfeature toolchain-funcs
DESCRIPTION="small daemon managing kernel hotplug events, similarly to udevd"
HOMEPAGE="https://skarnet.org/software/mdevd/"
SRC_URI="https://skarnet.org/software/mdevd/${P}.tar.gz"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
# Note: mdevd has optional support for nsss, which isn't packaged in gentoo
RDEPEND=">=dev-libs/skalibs-2.14.5.0:="
DEPEND="${RDEPEND}"
DOCS=( AUTHORS NEWS README doc/ examples )
src_configure() {
tc-export CC
# --with-dynlib and --with-sysdeps needs to match skalibs' --dynlibdir and --sysdepdir respectively
local myconf=(
--dynlibdir="/$(get_libdir)"
--libdir="/usr/$(get_libdir)/${PN}"
--sysconfdir=/etc
--with-dynlib="/$(get_libdir)"
--with-sysdeps="/usr/$(get_libdir)/skalibs/"
--enable-shared
--disable-allstatic
)
econf "${myconf[@]}"
}
src_compile() {
emake AR=$(tc-getAR) RANLIB=$(tc-getRANLIB)
}
pkg_postinst() {
optfeature "For +/-/& command directives in mdev.conf" dev-lang/execline
}
|
