blob: 7227334a0b398b7676c3b980d87ab4a70414f820 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="Brian Kernighan's pattern scanning and processing language"
HOMEPAGE="https://www.cs.princeton.edu/~bwk/btl.mirror/"
SRC_URI="https://github.com/onetrueawk/awk/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/awk-${PV}"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ppc ppc64 ~riscv ~s390 ~sparc x86"
BDEPEND="
app-alternatives/yacc
"
DOCS=( README.md FIXES )
src_compile() {
emake \
CC="$(tc-getCC)" \
HOSTCC="$(tc-getBUILD_CC)" \
CFLAGS="${CFLAGS}" \
CPPFLAGS="${CPPFLAGS} -DHAS_ISBLANK" \
ALLOC="${LDFLAGS}" \
YACC=$(type -p yacc) \
YFLAGS="-d -b awkgram"
}
src_install() {
newbin a.out "${PN}"
sed \
-e 's/awk/nawk/g' \
-e 's/AWK/NAWK/g' \
-e 's/Awk/Nawk/g' \
awk.1 > "${PN}".1 || die "manpage patch failed"
doman "${PN}.1"
einstalldocs
}
|
