blob: 9b88540f1fa8754e26ae308836fdffaca5b3c6f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
# Copyright 2020-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
inherit linux-info meson python-any-r1 systemd tmpfiles
DESCRIPTION="Linux application sandboxing and distribution framework"
HOMEPAGE="https://flatpak.org/"
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ~ppc64 ~riscv x86"
IUSE="doc introspection policykit seccomp systemd test X"
RESTRICT="!test? ( test )"
RDEPEND="
acct-group/flatpak
acct-user/flatpak
>=app-arch/libarchive-2.8:=
app-arch/zstd:=
>=app-crypt/gpgme-1.1.8:=
>=dev-libs/appstream-0.12:=
>=dev-libs/glib-2.56:2
>=dev-libs/libxml2-2.4:=
dev-libs/json-glib
dev-libs/libassuan:=
>=dev-util/ostree-2020.8:=[gpg(+)]
dev-util/ostree[curl]
>=gnome-base/dconf-0.26
gnome-base/gsettings-desktop-schemas
net-misc/curl
net-misc/socat
>=sys-apps/bubblewrap-0.10.0
sys-apps/dbus
>=sys-fs/fuse-3.1.1:3=
sys-apps/xdg-dbus-proxy
policykit? ( sys-auth/polkit )
X? (
x11-apps/xauth
x11-libs/libXau:=
)
x11-libs/gdk-pixbuf:2=
seccomp? ( sys-libs/libseccomp )
systemd? ( sys-apps/systemd )
"
DEPEND="${RDEPEND}"
BDEPEND="
>=dev-build/automake-1.13.4
>=sys-devel/gettext-0.18.2
virtual/pkgconfig
>=dev-util/gdbus-codegen-2.80.5-r1
dev-util/glib-utils
dev-util/gtk-doc
app-alternatives/yacc
$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
doc? (
app-text/xmlto
dev-libs/libxslt
)
test? (
net-misc/socat
sys-auth/polkit
)
"
PDEPEND="sys-apps/xdg-desktop-portal"
PATCHES=("${FILESDIR}/flatpak-1.16.3-glibc-2.43.patch")
python_check_deps() {
python_has_version "dev-python/pyparsing[${PYTHON_USEDEP}]"
}
pkg_setup() {
local CONFIG_CHECK="~USER_NS"
linux-info_pkg_setup
python-any-r1_pkg_setup
}
src_prepare() {
default
# This line fails because locales are in /usr/lib/locale/locale-archive.
sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
# QA Notice: The ebuild is installing to one or more unexpected directories:
# /usr/share/doc/flatpak
sed -i "s|docdir = get_option('datadir') / 'doc' / 'flatpak'|docdir = get_option('datadir') / 'flatpak'|g" \
meson.build || die
}
src_configure() {
local emesonargs=(
--localstatedir="${EPREFIX}"/var
-Ddbus_config_dir=/usr/share/dbus-1/system.d
-Dsystem_bubblewrap=bwrap
-Dsystem_dbus_proxy=xdg-dbus-proxy
-Dtmpfilesdir=/usr/lib/tmpfiles.d
$(meson_use policykit tests)
$(meson_use test tests)
$(meson_feature policykit system_helper)
$(meson_feature introspection gir)
$(meson_feature X xauth)
$(meson_feature doc docbook_docs)
$(meson_feature seccomp seccomp)
$(meson_feature systemd systemd)
)
meson_src_configure
}
src_install() {
meson_src_install
# https://projects.gentoo.org/qa/policy-guide/installed-files.html#pg0303
find "${ED}" -name '*.la' -delete || die
# resolve conflict with acct-user/flatpak for #856706
rm -rf "${ED}/usr/lib/sysusers.d"
if use systemd; then
systemd_dounit "${FILESDIR}"/flatpak-update.{service,timer}
fi
}
pkg_postinst() {
tmpfiles_process flatpak.conf
}
|
