blob: 88a5d2c2263b32de3662383b73cd14d050f5c43d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Built with autotools rather than cmake to avoid circular dep (bug #951525)
inherit multilib-minimal
DESCRIPTION="HTTP/2 C Library"
HOMEPAGE="https://nghttp2.org/"
if [[ ${PV} == 9999 ]] ; then
EGIT_REPO_URI="https://github.com/nghttp2/nghttp2.git"
inherit git-r3 autotools
else
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/nghttp2.asc
inherit verify-sig
SRC_URI="
https://github.com/nghttp2/nghttp2/releases/download/v${PV}/${P}.tar.xz
verify-sig? ( https://github.com/nghttp2/nghttp2/releases/download/v${PV}/${P}.tar.xz.asc )
"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
BDEPEND="verify-sig? ( sec-keys/openpgp-keys-nghttp2 )"
fi
LICENSE="MIT"
SLOT="0/1.14" # 1.<SONAME>
IUSE="debug hpack-tools systemd test utils xml"
RESTRICT="!test? ( test )"
RDEPEND="
hpack-tools? ( >=dev-libs/jansson-2.5:= )
utils? (
>=dev-libs/openssl-1.0.2:0=[-bindist(-),${MULTILIB_USEDEP}]
>=dev-libs/libev-4.15[${MULTILIB_USEDEP}]
net-dns/c-ares:=[${MULTILIB_USEDEP}]
>=virtual/zlib-1.2.3:=[${MULTILIB_USEDEP}]
)
systemd? ( >=sys-apps/systemd-209 )
xml? ( >=dev-libs/libxml2-2.7.7:2=[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}"
BDEPEND+=" virtual/pkgconfig"
src_prepare() {
default
[[ ${PV} == 9999 ]] && eautoreconf
}
multilib_src_configure() {
# TODO: enable HTTP3
# requires quictls/openssl, libngtcp2, libngtcp2_crypto_quictls, libnghttp3
local myeconfargs=(
--disable-examples
--disable-failmalloc
--disable-werror
--enable-threads
--without-jemalloc
$(use_enable debug)
$(multilib_native_use_enable hpack-tools)
$(multilib_native_use_with hpack-tools jansson)
$(multilib_native_use_with systemd)
$(multilib_native_use_enable utils app)
$(multilib_native_use_with xml libxml2)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
einstalldocs
find "${ED}"/usr -type f -name '*.la' -delete || die
}
|
