blob: 95b39fc4412778ebb864887d057c853cfe5025d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic multilib-minimal toolchain-funcs
DESCRIPTION="Lossy speech compression library and tool"
HOMEPAGE="https://www.quut.com/gsm/ https://tracker.debian.org/pkg/libgsm"
SRC_URI="https://www.quut.com/gsm/${P}.tar.gz"
S="${WORKDIR}/${PN}-$(ver_cut 1-2)-pl$(ver_cut 3)"
LICENSE="gsm"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
PATCHES=(
"${FILESDIR}"/${PN}-1.0.23-makefile.patch
)
DOCS=( ChangeLog MACHINES MANIFEST README )
src_prepare() {
default
multilib_copy_sources
}
src_configure() {
# From upstream Makefile. Define this if your host multiplies
# floats faster than integers, e.g. on a SPARCstation.
use sparc && append-flags -DUSE_FLOAT_MUL -DFAST
}
multilib_src_compile() {
local myemakeargs=(
CC="$(tc-getCC)"
LD="$(tc-getCC)"
AR="$(tc-getAR)"
RANLIB="$(tc-getRANLIB)"
SO_MAJOR=$(ver_cut 1)
SO_VER=${PV}
)
# bug #972569
emake -j1 CCFLAGS="${CFLAGS} -c -DNeedFunctionPrototypes=1 -fPIC" "${myemakeargs[@]}"
}
multilib_src_install() {
dodir /usr/bin /usr/$(get_libdir) /usr/include/gsm /usr/share/man/man{1,3}
local myemakeargs=(
CC="$(tc-getCC)"
LD="$(tc-getCC)"
AR="$(tc-getAR)"
RANLIB="$(tc-getRANLIB)"
INSTALL_ROOT="${ED}"/usr
GSM_INSTALL_LIB="${ED}"/usr/$(get_libdir)
GSM_INSTALL_INC="${ED}"/usr/include/gsm
GSM_INSTALL_MAN="${ED}"/usr/share/man/man3
TOAST_INSTALL_MAN="${ED}"/usr/share/man/man1
SO_MAJOR=$(ver_cut 1)
SO_VER=${PV}
)
# bug #972569
emake -j1 "${myemakeargs[@]}" install
dosym ../gsm/gsm.h /usr/include/libgsm/gsm.h
}
|
