blob: afbc2c7d5f1d60de868e7b5efa5f3b82adb6c8a4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..14} )
inherit cmake python-single-r1
DESCRIPTION="Tiling Wayland compositor based on Mir"
HOMEPAGE="https://github.com/miracle-wm-org/miracle-wm"
SRC_URI="https://github.com/miracle-wm-org/miracle-wm/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3+ MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="systemd test"
REQUIRED_USE="systemd? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
dev-cpp/yaml-cpp:=
dev-cpp/nlohmann_json
dev-libs/glib:2
dev-libs/json-c:=
dev-libs/libevdev
dev-libs/libpcre2:=
dev-libs/wayland
>=gui-libs/mir-2.18:=
media-libs/libglvnd
x11-base/xwayland
x11-libs/libxkbcommon
"
RDEPEND="
${COMMON_DEPEND}
systemd? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/dbus-next[${PYTHON_USEDEP}]
dev-python/tenacity[${PYTHON_USEDEP}]
')
)
"
DEPEND="
${COMMON_DEPEND}
media-libs/glm
"
BDEPEND="
virtual/pkgconfig
test? ( dev-cpp/gtest )
"
PATCHES=(
"${FILESDIR}/${PN}-0.6.1-conditional-tests.patch"
"${FILESDIR}/${PN}-0.7.0-disable-mirtest.patch"
"${FILESDIR}/${PN}-0.7.0-no-automagic.patch"
"${FILESDIR}/${PN}-0.8.3-mir-2.25-compat.patch"
)
pkg_setup() {
use systemd && python-single-r1_pkg_setup
}
src_prepare() {
cmake_src_prepare
use test || cmake_comment_add_subdirectory tests/
use systemd && python_fix_shebang session/usr/bin/libexec/miracle-wm-wait-sni-ready
}
src_configure() {
local mycmakeargs=(
-DSYSTEMD_INTEGRATION=$(usex systemd)
-DWITH_TESTS=$(usex test)
)
cmake_src_configure
}
src_test() {
"${BUILD_DIR}/tests/miracle-wm-tests" || die
"${BUILD_DIR}/miracle-wm-config/test_miracle_wm_config_c_api" || die
}
|
