blob: d36fc36f4adceb2087bcef6ed9a709618134b1ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit branding cmake flag-o-matic
DESCRIPTION="Toolkit for building desktop widgets using QtQuick"
HOMEPAGE="https://quickshell.org/"
if [[ "${PV}" = *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/quickshell-mirror/${PN^}.git"
else
SRC_URI="https://github.com/quickshell-mirror/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
fi
LICENSE="LGPL-3"
SLOT="0"
# Upstream recommends leaving all build options enabled by default
IUSE="
+jemalloc +sockets
+wayland +layer-shell +session-lock +toplevel-management
+hyprland +screencopy
+X +i3
+tray +pipewire +mpris +pam +policykit +greetd +upower +notifications
+bluetooth +networkmanager +crash-handler
"
REQUIRED_USE="
layer-shell? ( wayland )
session-lock? ( wayland )
toplevel-management? ( wayland )
hyprland? ( wayland )
screencopy? ( wayland )
i3? ( X )
"
RDEPEND="
dev-qt/qtbase:6=[dbus,vulkan,X?]
dev-qt/qtsvg:6=
dev-qt/qtdeclarative:6=
jemalloc? ( dev-libs/jemalloc )
wayland? (
dev-libs/wayland
dev-qt/qtwayland:6=
)
screencopy? (
x11-libs/libdrm
media-libs/mesa
)
X? ( x11-libs/libxcb )
pipewire? ( media-video/pipewire )
pam? ( sys-libs/pam )
policykit? (
sys-auth/polkit
dev-libs/glib
)
bluetooth? ( net-wireless/bluez )
networkmanager? ( net-misc/networkmanager )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
dev-cpp/cli11
dev-util/spirv-tools
dev-qt/qtshadertools:6
screencopy? ( dev-util/vulkan-headers )
wayland? (
dev-util/wayland-scanner
dev-libs/wayland-protocols
)
crash-handler? ( dev-cpp/cpptrace[unwind] )
"
DOCS=( README.md changelog/ )
src_configure() {
# -Werror=strict-aliasing
# https://github.com/quickshell-mirror/quickshell/issues/599
append-flags -fno-strict-aliasing
filter-lto
# hyprland controls all Hyprland sub-features as a group.
# i3 controls I3/Sway IPC.
# screencopy controls all screencopy backends (icc, wlr, hyprland-toplevel).
local _hyprland=$(usex hyprland)
local _screencopy=$(usex screencopy)
local _i3=$(usex i3)
local mycmakeargs=(
-DDISTRIBUTOR="${BRANDING_OS_NAME} GURU"
-DINSTALL_QML_PREFIX="$(get_libdir)/qt6/qml"
-DGIT_REVISION=${EGIT_COMMIT}
-DCRASH_HANDLER=$(usex crash-handler)
-DUSE_JEMALLOC=$(usex jemalloc)
-DSOCKETS=$(usex sockets)
-DWAYLAND=$(usex wayland)
-DWAYLAND_WLR_LAYERSHELL=$(usex layer-shell)
-DWAYLAND_SESSION_LOCK=$(usex session-lock)
-DWAYLAND_TOPLEVEL_MANAGEMENT=$(usex toplevel-management)
-DHYPRLAND=${_hyprland}
-DHYPRLAND_IPC=${_hyprland}
-DHYPRLAND_GLOBAL_SHORTCUTS=${_hyprland}
-DHYPRLAND_FOCUS_GRAB=${_hyprland}
-DHYPRLAND_SURFACE_EXTENSIONS=${_hyprland}
-DSCREENCOPY=${_screencopy}
-DSCREENCOPY_ICC=${_screencopy}
-DSCREENCOPY_WLR=${_screencopy}
-DSCREENCOPY_HYPRLAND_TOPLEVEL=${_screencopy}
-DX11=$(usex X)
-DI3=${_i3}
-DI3_IPC=${_i3}
-DSERVICE_STATUS_NOTIFIER=$(usex tray)
-DSERVICE_PIPEWIRE=$(usex pipewire)
-DSERVICE_MPRIS=$(usex mpris)
-DSERVICE_PAM=$(usex pam)
-DSERVICE_POLKIT=$(usex policykit)
-DSERVICE_GREETD=$(usex greetd)
-DSERVICE_UPOWER=$(usex upower)
-DSERVICE_NOTIFICATIONS=$(usex notifications)
-DBLUETOOTH=$(usex bluetooth)
-DNETWORK=$(usex networkmanager)
)
cmake_src_configure
}
|
