blob: e4ac576864b080ee62dbd7fdb66265d8fdd9aa57 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake dot-a
MY_PN="KDStateMachineEditor"
DESCRIPTION="Framework for creating Qt State Machine metacode using graphical user interfaces"
HOMEPAGE="https://github.com/KDAB/KDStateMachineEditor"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/KDAB/KDStateMachineEditor.git"
else
SRC_URI="https://github.com/KDAB/KDStateMachineEditor/releases/download/v${PV}/${P}.tar.gz"
KEYWORDS="~amd64"
S="${WORKDIR}/${MY_PN}-${PV}"
fi
LICENSE="LGPL-2.1"
SLOT="0"
IUSE="doc gui test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-qt/qtbase:6[gui,network,opengl,widgets]
dev-qt/qtdeclarative:6[widgets]
dev-qt/qtremoteobjects:6
dev-qt/qtscxml:6
media-gfx/graphviz:=
gui? ( dev-qt/qt5compat:6[qml] )
"
DEPEND="${RDEPEND}"
BDEPEND="
doc? (
app-text/doxygen
dev-qt/qttools:6[assistant]
media-gfx/graphviz
)
gui? ( dev-util/patchelf )
"
src_prepare() {
# set TEST_DATA_DIR for application env instead of test env.
if use gui; then
sed -e 's:${CMAKE_CURRENT_SOURCE_DIR}/data:'"${EPREFIX}"'/usr/share/'"${PN}"'/data:' \
-i CMakeLists.txt || die
fi
cmake_src_prepare
}
src_configure() {
# libkdstatemachineeditor_debuginterfacesource-qt6.a used by KSME-qt6Targets-relwithdebinfo.cmake
lto-guarantee-fat
local mycmakeargs=(
-DKDSME_DOCS=$(usex doc)
-DKDSME_EXAMPLES=OFF
-DKDSME_INTERNAL_GRAPHVIZ=OFF
)
use doc && mycmakeargs+=(
# prevent ${PF}-qt6
-DQCH_INSTALL_DIR="${EPREFIX}/usr/share/doc/${PF}/"
)
if use gui || use test; then
mycmakeargs+=( -DBUILD_TESTING=ON )
else
mycmakeargs+=( -DBUILD_TESTING=OFF )
fi
cmake_src_configure
}
src_test() {
# skip tests that use scxml files in modified TEST_DATA_DIR
use gui && CMAKE_SKIP_TESTS=(
test_layouter
test_scxmlimport
)
local -x QT_QPA_PLATFORM=offscreen
KDE_DEBUG=1 cmake_src_test
}
src_install() {
cmake_src_install
strip-lto-bytecode
if use gui; then
patchelf --remove-rpath "${BUILD_DIR}"/bin/${PN} || die
dobin "${BUILD_DIR}"/bin/${PN}
insinto /usr/share/${PN}
doins -r data
fi
use doc && docompress -x /usr/share/doc/${PF}/${PN}{-api.qch,.tags}
}
|
