blob: c5dfe9f5773b856dfe6f80d7c1db29e7beb95278 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=flit-core
PYPI_VERIFY_REPO=https://github.com/py-pdf/pypdf
PYTHON_COMPAT=( python3_{13..14} )
inherit distutils-r1 pypi
SAMPLE_COMMIT=818dc013ad1f537198e9fcfae8a6b0dffe25ffa3
DESCRIPTION="Python library to work with PDF files"
HOMEPAGE="
https://pypi.org/project/pypdf/
https://github.com/py-pdf/pypdf/
"
SRC_URI+="
test? (
https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
)
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
BDEPEND="
test? (
>=dev-python/cryptography-3.1[${PYTHON_USEDEP}]
dev-python/fonttools[${PYTHON_USEDEP}]
>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,zlib,${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
media-libs/jbig2dec[png]
)
"
EPYTEST_PLUGINS=( pytest-timeout )
EPYTEST_XDIST=1
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# probably requires extra deps
tests/test_appearance_stream.py::test_appearance_stream_rtl
# speed test, uses tons of memory
tests/test_filters.py::test_flatedecode__decode_png_prediction__speed
)
src_unpack() {
default
if use test; then
mv "sample-files-${SAMPLE_COMMIT}" "${S}"/sample-files || die
fi
}
python_test() {
epytest -o addopts= -m "not enable_socket"
}
|
