blob: fabd2d16d50f685d5a1a5eb2b4517b47d0e23c31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 2022-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=standalone
PYPI_VERIFY_REPO=https://github.com/python-poetry/poetry-core
PYTHON_TESTED=( pypy3_11 python3_{11..14} )
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_15 )
inherit distutils-r1 pypi
DESCRIPTION="Poetry PEP 517 Build Backend"
HOMEPAGE="
https://github.com/python-poetry/poetry-core/
https://pypi.org/project/poetry-core/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
IUSE="test"
RESTRICT="!test? ( test )"
# check inside vendors/pyproject.toml
# (note that some are indirect deps)
RDEPEND="
>=dev-python/fastjsonschema-2.21.2[${PYTHON_USEDEP}]
>=dev-python/lark-1.3.1[${PYTHON_USEDEP}]
>=dev-python/packaging-26.2[${PYTHON_USEDEP}]
"
BDEPEND="
${RDEPEND}
test? (
$(python_gen_cond_dep '
dev-python/build[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/tomli-w[${PYTHON_USEDEP}]
>=dev-python/trove-classifiers-2022.5.19[${PYTHON_USEDEP}]
>=dev-python/virtualenv-20.21[${PYTHON_USEDEP}]
dev-vcs/git
' "${PYTHON_TESTED[@]}")
)
"
src_prepare() {
# remove vendoring of dependencies
rm -r src/poetry/core/_vendor || die
sed -e '/__vendor_site__/d' -i src/poetry/core/__init__.py || die
distutils-r1_src_prepare
}
python_test() {
if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
einfo "Skipping tests on ${EPYTHON} (unported deps)"
return
fi
# Poetry expects test to be run inside a git repository, otherwise
# VCS-related logic doesn't get triggered. An empty repository
# suffices, though.
git init || die
local EPYTEST_PLUGINS=( pytest-mock )
epytest
}
|
