blob: 777a6ba6f7b8d61c687221fada1a7ef87e873611 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit dune
DESCRIPTION="JSON parsing and pretty-printing library for OCaml"
HOMEPAGE="https://github.com/ocaml-community/yojson/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/ocaml-community/${PN}"
else
SRC_URI="https://github.com/ocaml-community/${PN}/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
fi
LICENSE="BSD"
SLOT="0/${PV}"
IUSE="examples +ocamlopt test"
RESTRICT="!test? ( test )"
BDEPEND="
test? ( dev-ml/alcotest )
"
src_prepare() {
default
# let's not build this
rm bench/dune yojson-bench.opam || die
}
src_compile() {
dune-compile "${PN}"
}
src_test() {
dune-test "${PN}"
}
src_install() {
dune_src_install
if use examples; then
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
}
|
