dev-lua/lua-utf8-simple/lua-utf8-simple-0_pre20150305.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LUA_COMPAT=( lua5-{1,3,4} luajit )

inherit lua

DESCRIPTION="Basic UTF8-handling functions for Lua"
HOMEPAGE="https://github.com/blitmap/lua-utf8-simple"
EGIT_COMMIT="7ef030750d8e408ac5d724aefab2ec8769731005"
SRC_URI="https://github.com/blitmap/lua-utf8-simple/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"

S="${WORKDIR}/${PN}-${EGIT_COMMIT}"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"

REQUIRED_USE="${LUA_REQUIRED_USE}"

DEPEND="${LUA_DEPS}"
RDEPEND="${DEPEND}"

lua_src_test() {
	${ELUA} shitty_testcases.lua || die
}

src_test() {
	lua_foreach_impl lua_src_test
}

lua_src_install() {
	insinto $(lua_get_lmod_dir)
	doins utf8_simple.lua
}

src_install() {
	lua_foreach_impl lua_src_install
	dodoc README.md
}