blob: b21484f6d7f0e53618c5c7c998d8ae5661a4d30c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 2023-2025 BaldEagleOS Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit multilib-minimal toolchain-funcs
# Different date format used upstream.
RE2_VER=${PV#0.}
RE2_VER=${RE2_VER//./-}
DESCRIPTION="An efficient, principled regular expression library"
HOMEPAGE="https://github.com/google/re2"
SRC_URI="https://github.com/google/re2/archive/refs/tags/${RE2_VER}.tar.gz -> re2-${RE2_VER}.tar.gz"
LICENSE="BSD"
# NOTE: Always run libre2 through abi-compliance-checker!
# https://abi-laboratory.pro/tracker/timeline/re2/
SONAME="11"
SLOT="0/${SONAME}"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc x86"
IUSE="icu"
BDEPEND="icu? ( virtual/pkgconfig )"
DEPEND="
icu? ( dev-libs/icu:0=[${MULTILIB_USEDEP}] )
dev-cpp/abseil-cpp
"
RDEPEND="${DEPEND}"
S="${WORKDIR}/re2-${RE2_VER}"
DOCS=( CONTRIBUTING.md README.md doc/syntax.txt )
HTML_DOCS=( doc/syntax.html )
src_prepare() {
default
grep -q "^SONAME=${SONAME}\$" Makefile || die "SONAME mismatch"
if use icu; then
sed -i -e 's:^# \(\(CC\|LD\)ICU=.*\):\1:' Makefile || die
fi
multilib_copy_sources
}
src_configure() {
tc-export AR CXX
}
multilib_src_compile() {
emake SONAME="${SONAME}" shared
}
multilib_src_install() {
emake SONAME="${SONAME}" DESTDIR="${D}" prefix="${EPREFIX}/usr" libdir="\$(exec_prefix)/$(get_libdir)" shared-install
}
|
