blob: 666166de1caa03f7acc2bcee74519fe3a6b598ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="Library for solving packages and reading repositories"
HOMEPAGE="https://github.com/openSUSE/libsolv"
SRC_URI="https://github.com/openSUSE/libsolv/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="expat zchunk"
RDEPEND="
app-arch/bzip2
app-arch/rpm
app-arch/xz-utils
app-arch/zstd:=
virtual/zlib:=
expat? ( dev-libs/expat )
!expat? ( dev-libs/libxml2:= )
zchunk? ( app-arch/zchunk )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
src_prepare() {
# remove forced CFLAGS -g -O2; bug 936869
sed "/CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE^^}/d" -i CMakeLists.txt || die
# raise cmake minimum version for future compatibility
# https://github.com/openSUSE/libsolv/pull/581#issuecomment-2751109001
sed "/CMAKE_MINIMUM_REQUIRED/s/3.5/3.10/" -i CMakeLists.txt || die
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DENABLE_RPMDB=ON
-DENABLE_RPMMD=ON
-DENABLE_RPMPKG_LIBRPM=ON
-DENABLE_COMPS=ON
-DENABLE_DEBIAN=OFF
-DENABLE_APK=OFF
-DENABLE_LZMA_COMPRESSION=ON
-DENABLE_BZIP2_COMPRESSION=ON
-DENABLE_ZSTD_COMPRESSION=ON
-DWITH_SYSTEM_ZCHUNK=$(usex zchunk)
-DWITH_LIBXML2=$(usex !expat)
-DENABLE_COMPLEX_DEPS=ON
)
cmake_src_configure
}
|
