blob: 92e4dc38092dd35ba3b03edcd3d18d76f69c73b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit dot-a java-vm-2 toolchain-funcs
abi_uri() {
local baseuri="https://github.com/adoptium/temurin$(ver_cut 1)-binaries/releases/download/jdk-${MY_PV}/"
local musl=
local os=linux
local libc=glibc
case ${2} in
*-macos) os=mac ;;
*-solaris) os=solaris ;;
esac
if [[ ${3} == musl ]]; then
os=alpine-linux
musl=true
libc=musl
fi
if [[ ${os} == mac ]]; then
libc=
fi
echo "${2-$1}? (
${musl:+ elibc_musl? ( }
${baseuri}/OpenJDK$(ver_cut 1)U-jdk_${1}_${os}_hotspot_${MY_PV//+/_}.tar.gz
static-libs? (
${baseuri}/OpenJDK$(ver_cut 1)U-static-libs${libc:+-$libc}_${1}_${os}_hotspot_${MY_PV//+/_}.tar.gz
)
${musl:+ ) } )"
}
MY_PV=${PV/_p/+}
DESCRIPTION="Prebuilt Java JDK binaries provided by Eclipse Temurin"
HOMEPAGE="https://adoptium.net"
SRC_URI="
$(abi_uri aarch64 arm64)
$(abi_uri aarch64 arm64-macos)
$(abi_uri arm)
$(abi_uri ppc64le ppc64)
$(abi_uri x64 amd64)
$(abi_uri x64 amd64 musl)
$(abi_uri riscv64 riscv)
$(abi_uri x64 x64-macos)
"
S="${WORKDIR}/jdk-${MY_PV}"
LICENSE="GPL-2-with-classpath-exception"
SLOT=$(ver_cut 1)
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x64-macos"
IUSE="alsa cups headless-awt selinux source static-libs"
RDEPEND="
>=sys-apps/baselayout-java-0.1.0-r1
kernel_linux? (
media-libs/fontconfig:1.0
media-libs/freetype:2
media-libs/harfbuzz
elibc_glibc? ( >=sys-libs/glibc-2.2.5:* )
elibc_musl? ( sys-libs/musl )
virtual/zlib:=
alsa? ( media-libs/alsa-lib )
cups? ( net-print/cups )
selinux? ( sec-policy/selinux-java )
!headless-awt? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXi
x11-libs/libXrender
x11-libs/libXtst
)
)"
RESTRICT="preserve-libs splitdebug"
QA_PREBUILT="*"
pkg_pretend() {
if [[ "$(tc-is-softfloat)" != "no" ]]; then
die "These binaries require a hardfloat system."
fi
}
src_unpack() {
default
if [[ ${A} == *_mac_* ]] ; then
mv -v "${S}/Contents/Home/"* "${S}" || die
rm -Rf "${S}/Contents" # drop macOS executable
fi
}
src_install() {
local dest="/opt/${P}"
local ddest="${ED}/${dest#/}"
if use static-libs ; then
cd "${S}"-static-libs/lib/static/*/* || die
cp -pPR * "${S}"/lib || die
strip-lto-bytecode "${S}"/lib || die
fi
cd "${S}"
# https://bugs.gentoo.org/922741
docompress "${dest}/man"
# on macOS if they would exist they would be called .dylib, but most
# importantly, there are no different providers, so everything
# that's shipped works.
if [[ ${A} != *_mac_* ]] ; then
# Not sure why they bundle this as it's commonly available and they
# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
# also has an explicit dependency while Oracle seemingly dlopens it.
rm -vf lib/libfreetype.so || die
# prefer system copy # https://bugs.gentoo.org/776676
rm -vf lib/libharfbuzz.so || die
# Oracle and IcedTea have libjsoundalsa.so depending on
# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
if ! use alsa ; then
rm -v lib/libjsound.* || die
fi
if use headless-awt ; then
rm -v lib/lib*{[jx]awt,splashscreen}* || die
fi
fi
if ! use source ; then
rm -v lib/src.zip || die
fi
rm -v lib/security/cacerts || die
dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
dodir "${dest}"
cp -pPR * "${ddest}" || die
# provide stable symlink
dosym "${P}" "/opt/${PN}-${SLOT}"
java-vm_install-env "${FILESDIR}"/${PN}.env.sh
java-vm_set-pax-markings "${ddest}"
java-vm_revdep-mask
java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
}
pkg_postinst() {
java-vm-2_pkg_postinst
}
|
