blob: b0f3a06d5e919e244969594b41b58816b3d36334 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
inherit cmake
DESCRIPTION="Migemo library implementation in C"
HOMEPAGE="https://www.kaoriya.net/software/cmigemo/"
SRC_URI="https://github.com/koron/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE="unicode vim"
RDEPEND=">=app-dicts/migemo-dict-200812[unicode=]"
DEPEND="${RDEPEND}"
PATCHES=( "${FILESDIR}"/${PN}-vim.patch )
DOCS=( doc/README_ja.txt )
src_configure() {
local mycmakeargs=(
-DBUILD_DICT=OFF
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
local dat
if use unicode; then
for dat in dict/*.dat; do
cp "${dat}" "${BUILD_DIR}"/${dat##*/} || die
done
else
for dat in dict/*.dat; do
iconv -f UTF-8 -t EUC-JISX0213 "${dat}" >"${BUILD_DIR}"/${dat##*/} || die
done
fi
}
src_install() {
cmake_src_install
insinto /usr/share/migemo
doins "${BUILD_DIR}"/*.dat
if use vim; then
insinto /usr/share/vim/vimfiles/plugin
doins misc/vim/migemo.vim
insinto /usr/share/vim/vimfiles/doc
doins misc/vim/vimigemo.txt
fi
}
|
