blob: 09126e45ab689149a36be699ce96efb906937011 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 2020-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..14} )
PYTHON_REQ_USE="xml(+)"
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 optfeature verify-sig
DESCRIPTION="Metadata Anonymisation Toolkit: handy tool to trash your metadata"
HOMEPAGE="https://0xacab.org/jvoisin/mat2"
SIG_UPLOAD_HASH="060efa77668fa7f6d9baeb8a327857af"
SRC_URI="
https://0xacab.org/jvoisin/${PN}/-/archive/${PV}/${P}.tar.gz
verify-sig? ( https://0xacab.org/-/project/1139/uploads/${SIG_UPLOAD_HASH}/${P}.tar.gz.asc )
"
LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
app-text/poppler[introspection,cairo]
dev-libs/glib:2
dev-python/pycairo:0[${PYTHON_USEDEP}]
dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
gnome-base/librsvg[introspection]
media-libs/mutagen:0[${PYTHON_USEDEP}]
x11-libs/gdk-pixbuf:2[introspection,jpeg,tiff]
"
BDEPEND="
verify-sig? ( >sec-keys/openpgp-keys-jvoisin-20200714 )
test? (
media-libs/exiftool:*
media-video/ffmpeg[lame,vorbis]
)
"
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/jvoisin.asc
DOCS=( doc {CHANGELOG,CONTRIBUTING,INSTALL,README}.md )
distutils_enable_tests unittest
src_prepare() {
sed -i '/data_files/d' setup.py || die
distutils-r1_src_prepare
}
src_test() {
if has_version -b sys-apps/bubblewrap; then
# Double sandboxing is not possible
has usersandbox ${FEATURES} && return 0
fi
distutils-r1_src_test
}
src_install() {
distutils-r1_src_install
doman doc/mat2.1
}
pkg_postinst() {
optfeature "misc file format support" media-libs/exiftool
optfeature "sandboxing" sys-apps/bubblewrap
optfeature "video support" media-video/ffmpeg
}
|
