blob: a7cd052103121a84a553c1bca32dc2ca2a768ad7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 optfeature pypi systemd
DESCRIPTION="Tools for ovmf/armvirt firmware volumes"
HOMEPAGE="
https://gitlab.com/kraxel/virt-firmware
https://pypi.org/project/virt-firmware/
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
RDEPEND="
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/pefile[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
"
# Need systemd-detect-virt
BDEPEND="
test? (
sys-apps/systemd
)
"
distutils_enable_tests unittest
python_prepare_all() {
# Requires crypt module removed in py3.13
rm virt/qemutest/cloudinit.py || die
sed -e '/from virt.qemutest.cloudinit import CloudInitISO/d' \
-i tests/tests.py || die
distutils-r1_python_prepare_all
}
python_test() {
eunittest tests
}
python_install_all() {
distutils-r1_python_install_all
doman man/*.1
doinitd "${FILESDIR}/kernel-bootcfg-boot-successful"
systemd_dounit systemd/kernel-bootcfg-boot-successful.service
# Use our own provided by sys-kernel/installkernel[efistub,systemd]
#exeinto /usr/lib/kernel/install.d
#doexe systemd/99-uki-uefi-setup.install
}
pkg_postinst() {
optfeature "automatically updating UEFI configuration on each kernel installation or removal" \
"sys-kernel/installkernel[systemd,efistub]"
}
|
