blob: 91246ffa2e31e4fe74dd42a3ee1a9843192ca448 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module linux-info
DESCRIPTION="Work with remote container images registries"
HOMEPAGE="https://github.com/podman-container-tools/skopeo"
if [[ ${PV} == 9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/podman-container-tools/skopeo.git"
else
SRC_URI="https://github.com/podman-container-tools/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm64"
fi
# main
LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
SLOT="0"
IUSE="btrfs rootless selinux"
RESTRICT="test"
DEPEND="
>=app-crypt/gpgme-1.5.5:=
dev-db/sqlite:3
btrfs? ( >=sys-fs/btrfs-progs-4.0.1 )
rootless? ( sys-apps/shadow:= )
selinux? ( sec-policy/selinux-podman sys-libs/libselinux:= )
"
RDEPEND="${DEPEND}
>=app-containers/container-libs-0.68.0
"
BDEPEND="
dev-go/go-md2man
>=dev-lang/go-1.25.7
"
PATCHES=( "${FILESDIR}"/handle-conflicts-with-c-libs-pr2173.patch )
pkg_setup() {
use btrfs && CONFIG_CHECK+=" ~BTRFS_FS"
linux-info_pkg_setup
}
run_make() {
local emakeflags=(
BTRFS_BUILD_TAG="$(usex btrfs '' 'exclude_graphdriver_btrfs')"
LIBSUBID_BUILD_TAG="$(usex rootless 'libsubid' '')"
SQLITE_BUILD_TAG="libsqlite3"
PREFIX="${EPREFIX}/usr"
)
emake "${emakeflags[@]}" "$@"
}
src_compile() {
run_make
}
src_install() {
run_make "DESTDIR=${D}" install
}
|
