1 files changed, 0 insertions, 171 deletions
diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-5.10.250.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-5.10.250.ebuild
deleted file mode 100644
index af306b68f731..000000000000
--- a/sys-kernel/gentoo-kernel/gentoo-kernel-5.10.250.ebuild
+++ /dev/null
@@ -1,171 +0,0 @@
-# Copyright 2020-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit kernel-build toolchain-funcs verify-sig
-
-BASE_P=linux-${PV%.*}
-PATCH_PV=${PV%_p*}
-PATCHSET=linux-gentoo-patches-5.10.248
-# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
-CONFIG_VER=5.10.12
-CONFIG_HASH=836165dd2dff34e4f2c47ca8f9c803002c1e6530
-GENTOO_CONFIG_VER=g17
-SHA256SUM_DATE=20260211
-
-DESCRIPTION="Linux kernel built with Gentoo patches"
-HOMEPAGE="
-	https://wiki.gentoo.org/wiki/Project:Distribution_Kernel
-	https://www.kernel.org/
-"
-SRC_URI+="
-	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${BASE_P}.tar.xz
-	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/patch-${PATCH_PV}.xz
-	https://distfiles.gentoo.org/pub/proj/dist-kernel/patchsets/$(ver_cut 1-2)/${PATCHSET}.tar.xz
-	https://github.com/projg2/gentoo-kernel-config/archive/${GENTOO_CONFIG_VER}.tar.gz
-		-> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
-	verify-sig? (
-		https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/sha256sums.asc
-			-> linux-$(ver_cut 1).x-sha256sums-${SHA256SUM_DATE}.asc
-	)
-	amd64? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-x86_64-fedora.config
-			-> kernel-x86_64-fedora.config.${CONFIG_VER}
-	)
-	arm64? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-aarch64-fedora.config
-			-> kernel-aarch64-fedora.config.${CONFIG_VER}
-	)
-	ppc64? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-ppc64le-fedora.config
-			-> kernel-ppc64le-fedora.config.${CONFIG_VER}
-	)
-	x86? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-i686-fedora.config
-			-> kernel-i686-fedora.config.${CONFIG_VER}
-	)
-"
-S=${WORKDIR}/${BASE_P}
-
-KEYWORDS="amd64 ~arm arm64 ~hppa ~ppc ppc64 ~sparc x86"
-IUSE="debug experimental hardened"
-REQUIRED_USE="
-	arm? ( savedconfig )
-	hppa? ( savedconfig )
-	sparc? ( savedconfig )
-"
-
-RDEPEND="
-	!sys-kernel/gentoo-kernel-bin:${SLOT}
-"
-BDEPEND="
-	debug? ( dev-util/pahole )
-	verify-sig? ( >=sec-keys/openpgp-keys-kernel-20250702 )
-"
-PDEPEND="
-	>=virtual/dist-kernel-${PV}
-"
-
-QA_FLAGS_IGNORED="
-	usr/src/linux-.*/scripts/gcc-plugins/.*.so
-	usr/src/linux-.*/vmlinux
-	usr/src/linux-.*/arch/powerpc/kernel/vdso.*/vdso.*.so.dbg
-"
-
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/kernel.org.asc
-
-src_unpack() {
-	if use verify-sig; then
-		cd "${DISTDIR}" || die
-		verify-sig_verify_signed_checksums \
-			"linux-$(ver_cut 1).x-sha256sums-${SHA256SUM_DATE}.asc" \
-			sha256 "${BASE_P}.tar.xz patch-${PATCH_PV}.xz"
-		cd "${WORKDIR}" || die
-	fi
-
-	default
-}
-
-src_prepare() {
-	local patch
-	eapply "${WORKDIR}/patch-${PATCH_PV}"
-	for patch in "${WORKDIR}/${PATCHSET}"/*.patch; do
-		eapply "${patch}"
-		# non-experimental patches always finish with Gentoo Kconfig
-		# when ! use experimental, stop applying after it
-		if [[ ${patch} == *Add-Gentoo-Linux-support-config-settings* ]] &&
-			! use experimental
-		then
-			break
-		fi
-	done
-
-	default
-
-	# add Gentoo patchset version
-	local extraversion=${PV#${PATCH_PV}}
-	sed -i -e "s:^\(EXTRAVERSION =\).*:\1 ${extraversion/_/-}:" Makefile || die
-
-	local biendian=false
-
-	# prepare the default config
-	case ${ARCH} in
-		arm | hppa | sparc)
-			> .config || die
-		;;
-		amd64)
-			cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die
-			;;
-		arm64)
-			cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die
-			biendian=true
-			;;
-		ppc)
-			# assume powermac/powerbook defconfig
-			# we still package.use.force savedconfig
-			cp "${WORKDIR}/${BASE_P}/arch/powerpc/configs/pmac32_defconfig" .config || die
-			;;
-		ppc64)
-			cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die
-			biendian=true
-			;;
-		x86)
-			cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die
-			;;
-		*)
-			die "Unsupported arch ${ARCH}"
-			;;
-	esac
-
-	local myversion="-gentoo-dist"
-	use hardened && myversion+="-hardened"
-	echo "CONFIG_LOCALVERSION=\"${myversion}\"" > "${T}"/version.config || die
-	local dist_conf_path="${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"
-
-	local merge_configs=(
-		"${T}"/version.config
-		"${dist_conf_path}"/base.config
-	)
-	use debug || merge_configs+=(
-		"${dist_conf_path}"/no-debug.config
-	)
-	if use hardened; then
-		merge_configs+=( "${dist_conf_path}"/hardened-base.config )
-
-		tc-is-gcc && merge_configs+=( "${dist_conf_path}"/hardened-gcc-plugins.config )
-
-		if [[ -f "${dist_conf_path}/hardened-${ARCH}.config" ]]; then
-			merge_configs+=( "${dist_conf_path}/hardened-${ARCH}.config" )
-		fi
-	fi
-
-	# this covers ppc64 and aarch64_be only for now
-	if [[ ${biendian} == true && $(tc-endian) == big ]]; then
-		merge_configs+=( "${dist_conf_path}/big-endian.config" )
-	fi
-
-	use secureboot && merge_configs+=( "${dist_conf_path}/secureboot.config" )
-
-	kernel-build_merge_configs "${merge_configs[@]}"
-}