3 files changed, 82 insertions, 7 deletions
diff --git a/media-libs/libsndfile/Manifest b/media-libs/libsndfile/Manifest
index b17ea6636334..bc6548cf102c 100644
--- a/media-libs/libsndfile/Manifest
+++ b/media-libs/libsndfile/Manifest
@@ -1 +1,2 @@
 DIST libsndfile-1.0.30.tar.bz2 852320 BLAKE2B 00bd558a3d8645f4ad03fba38c31fcea25d30bea4b6f1a785b4b31b0da61bfa6a6f7df1bd7907c95c543cce8ee6766032d2e614eb285f2fc529146cb1d319517 SHA512 c4be4bc57df880da81570889a80256ba4567f2c7d6bdfb38f3803c55f616278160e962544bfac32e53b613b8fdf2a2644d8da9ee778747c32cb681a0fd5aab00
+DIST libsndfile-1.0.31.tar.bz2 875335 BLAKE2B 33e3c3d111427e829d8233aec52c227188834936839da9a04cf1ea5d2595d6a3127e7ce86d7686ca0336cca2017e6e2466845c27c7fc399efae34a0902316e41 SHA512 62202092e5cac6346fd3c0a977380e9bf888fc59d08c9c9707dc254a8ef6ed6356da2ab0430bb970c7b06ba5bb1dafa5d7b0fe13898834c1fe4acb16f409f0e1
diff --git a/media-libs/libsndfile/libsndfile-1.0.31.ebuild b/media-libs/libsndfile/libsndfile-1.0.31.ebuild
new file mode 100644
index 000000000000..90b6bd098c55
--- /dev/null
+++ b/media-libs/libsndfile/libsndfile-1.0.31.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/libsndfile/libsndfile.git"
+else
+	SRC_URI="https://github.com/libsndfile/libsndfile/releases/download/${PV}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+inherit python-any-r1 multilib-minimal
+
+DESCRIPTION="C library for reading and writing files containing sampled sound"
+HOMEPAGE="https://libsndfile.github.io/libsndfile/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="alsa minimal sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!minimal? (
+		media-libs/flac:=[${MULTILIB_USEDEP}]
+		media-libs/libogg:=[${MULTILIB_USEDEP}]
+		media-libs/libvorbis:=[${MULTILIB_USEDEP}]
+		media-libs/opus:=[${MULTILIB_USEDEP}]
+	)
+	alsa? ( media-libs/alsa-lib:= )
+	sqlite? ( dev-db/sqlite )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )"
+if [[ ${PV} == *9999 ]]; then
+	BDEPEND+="
+		${PYTHON_DEPS}
+		sys-devel/autogen
+	"
+fi
+
+pkg_setup() {
+	if use test || [[ ${PV} == *9999 ]]; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--disable-octave \
+		--disable-static \
+		--disable-werror \
+		$(use_enable !minimal external-libs) \
+		$(multilib_native_enable full-suite) \
+		$(multilib_native_use_enable alsa) \
+		$(multilib_native_use_enable sqlite) \
+		PYTHON="${EPYTHON}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/media-libs/libsndfile/libsndfile-9999.ebuild b/media-libs/libsndfile/libsndfile-9999.ebuild
index 24aa4ffa35b8..90b6bd098c55 100644
--- a/media-libs/libsndfile/libsndfile-9999.ebuild
+++ b/media-libs/libsndfile/libsndfile-9999.ebuild
@@ -7,19 +7,19 @@ PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
 if [[ ${PV} == *9999 ]]; then
 	inherit autotools git-r3
-	EGIT_REPO_URI="https://github.com/erikd/libsndfile.git"
+	EGIT_REPO_URI="https://github.com/libsndfile/libsndfile.git"
 else
-	SRC_URI="https://github.com/erikd/libsndfile/releases/download/v${PV}/${P}.tar.bz2"
+	SRC_URI="https://github.com/libsndfile/libsndfile/releases/download/${PV}/${P}.tar.bz2"
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
 fi
 inherit python-any-r1 multilib-minimal
 
 DESCRIPTION="C library for reading and writing files containing sampled sound"
-HOMEPAGE="https://www.mega-nerd.com/libsndfile"
+HOMEPAGE="https://libsndfile.github.io/libsndfile/"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="alsa minimal sqlite static-libs test"
+IUSE="alsa minimal sqlite test"
 RESTRICT="!test? ( test )"
 
 RDEPEND="
@@ -57,8 +57,8 @@ src_prepare() {
 multilib_src_configure() {
 	ECONF_SOURCE="${S}" econf \
 		--disable-octave \
+		--disable-static \
 		--disable-werror \
-		$(use_enable static-libs static) \
 		$(use_enable !minimal external-libs) \
 		$(multilib_native_enable full-suite) \
 		$(multilib_native_use_enable alsa) \
@@ -69,6 +69,6 @@ multilib_src_configure() {
 multilib_src_install_all() {
 	einstalldocs
 
-	# package provides .pc files
-	find "${D}" -name '*.la' -delete || die
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
 }