1 files changed, 43 insertions, 0 deletions
diff --git a/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-49.1.ebuild b/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-49.1.ebuild
new file mode 100644
index 000000000000..620c9f57a1e7
--- /dev/null
+++ b/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-49.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Collection of GSettings schemas for GNOME desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gsettings-desktop-schemas"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="+introspection"
+
+BDEPEND="
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Use generic sans and monospace aliases
+	"${FILESDIR}"/49.0-default-fonts.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}