1 files changed, 50 insertions, 0 deletions
diff --git a/dev-util/bash-language-server/bash-language-server-5.6.0.ebuild b/dev-util/bash-language-server/bash-language-server-5.6.0.ebuild
new file mode 100644
index 000000000000..8165351e266e
--- /dev/null
+++ b/dev-util/bash-language-server/bash-language-server-5.6.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+#@formatter:off
+EAPI=8
+
+inherit optfeature
+
+DESCRIPTION="A language server for Bash"
+HOMEPAGE="https://github.com/bash-lsp/bash-language-server"
+SRC_URI="
+	mirror://npm/${PN}/-/${P}.tgz
+	https://github.com/ingenarel/guru-depfiles/releases/download/${P}-deps.tar.xz/${P}-deps.tar.xz
+"
+S="${WORKDIR}"
+
+# NOTE: to generate the dependency tarball:
+#       npm --cache ./npm-cache install $(portageq envvar DISTDIR)/${P}.tgz
+#       tar -caf ${P}-deps.tar.xz npm-cache
+
+LICENSE="BSD-2 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND=">=net-libs/nodejs-18.19.30"
+BDEPEND=">=net-libs/nodejs-18.19.30[npm]"
+
+src_unpack() {
+	cd "${T}" || die "Could not cd to temporary directory"
+	unpack ${P}-deps.tar.xz
+}
+
+src_install() {
+	npm \
+		--offline \
+		--verbose \
+		--progress false \
+		--foreground-scripts \
+		--global \
+		--prefix "${ED}"/usr \
+		--cache "${T}"/npm-cache \
+		install "${DISTDIR}"/${P}.tgz || die "npm install failed"
+
+	cd "${ED}"/usr/$(get_libdir)/node_modules/${PN} || die "cd failed"
+	einstalldocs
+}
+
+pkg_postinst() {
+	optfeature "linting support" dev-util/shellcheck dev-util/shellcheck-bin
+}