2 files changed, 56 insertions, 0 deletions
diff --git a/dev-tex/pythontex/Manifest b/dev-tex/pythontex/Manifest
index 027ae858e5bb..73534d0963f2 100644
--- a/dev-tex/pythontex/Manifest
+++ b/dev-tex/pythontex/Manifest
@@ -1 +1,2 @@
 DIST pythontex-0.18.tar.gz 1807531 BLAKE2B 0f3293043780e93290fb9b3988513f919983a1a19c18344c6d5b1223dea40310581c0b5938da695485516648db3b23dbbef3eb40091f2ccd8f5a7576179043a7 SHA512 ad7dcb91d7df3eb37cdfaab870001f70976a55ca300c029ae931ade53103cbd71f7c3a4fa5d1360fdd1d9fc092f39c0427f13d2328033197057dcbc490d4ca7b
+DIST pythontex-0.18_p20251112.tar.gz 1808282 BLAKE2B 25265a10716b3a409f8998b73e9011897932730d983796d98cb0c354fc432134a2f987f6c803ff389d43073de1022e7b812087e666d5ade51651c9f3aa474232 SHA512 e29082f885c2183b1243bf3d4525ab0bede4d14d80fc90df1f10fbbf29f0cfcdb4b03e8124209491a3bcfd5cf022abc81f6a573d818db0a4e187bb0b130c379b
diff --git a/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild b/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild
new file mode 100644
index 000000000000..1801db4b3a41
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit latex-package python-r1
+
+COMMIT="63484d82131f8f621dccde9c9649c98ff4e322f9"
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/pythontex/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="LPPL-1.3 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+IUSE="doc highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-texlive/texlive-latexextra-2023
+	dev-tex/pgf
+"
+RDEPEND="${DEPEND}
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+}
+
+src_install() {
+	dodoc *rst
+	use doc && dodoc ${PN}_quickstart/*pdf ${PN}/*pdf
+
+	cd ${PN} || die
+
+	installation() {
+		python_domodule {de,}${PN}3.py
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall sty
+}