summaryrefslogtreecommitdiff
path: root/dev-python
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python')
-rw-r--r--dev-python/humanize/Manifest1
-rw-r--r--dev-python/humanize/humanize-4.2.1.ebuild29
-rw-r--r--dev-python/hypothesis/Manifest1
-rw-r--r--dev-python/hypothesis/hypothesis-6.47.4.ebuild76
-rw-r--r--dev-python/jupyter_server/Manifest1
-rw-r--r--dev-python/jupyter_server/jupyter_server-1.18.0.ebuild76
-rw-r--r--dev-python/nuitka/Manifest1
-rw-r--r--dev-python/nuitka/nuitka-0.9.ebuild49
-rw-r--r--dev-python/oslo-utils/Manifest1
-rw-r--r--dev-python/oslo-utils/oslo-utils-6.0.0.ebuild64
-rw-r--r--dev-python/pandas/Manifest1
-rw-r--r--dev-python/pandas/pandas-1.4.3.ebuild197
-rw-r--r--dev-python/pycson/pycson-0.8-r3.ebuild2
-rw-r--r--dev-python/speg/speg-0.3-r3.ebuild2
-rw-r--r--dev-python/sqlalchemy/Manifest1
-rw-r--r--dev-python/sqlalchemy/sqlalchemy-1.4.38.ebuild93
-rw-r--r--dev-python/uvicorn/Manifest1
-rw-r--r--dev-python/uvicorn/uvicorn-0.18.1.ebuild55
18 files changed, 649 insertions, 2 deletions
diff --git a/dev-python/humanize/Manifest b/dev-python/humanize/Manifest
index 56452d90703d..e98f4c69b733 100644
--- a/dev-python/humanize/Manifest
+++ b/dev-python/humanize/Manifest
@@ -1,2 +1,3 @@
DIST humanize-4.1.0.tar.gz 73777 BLAKE2B fcbde90977ae9fcd706e423767b1d5617fd118ae8903283f4b307ee05a5adffb3bb68305e5d758b1860d37a37d22766127d84479d331a7ed05c83cd53e5b0829 SHA512 7e2d92ed44e773bd8a53d4b151e80949fda057d8f4a52003826efa9ec2a569360b76663d44c3d1239fd2ecdd5365357d3fac72a395d1c10d5207b4a27f248878
DIST humanize-4.2.0.tar.gz 75169 BLAKE2B dc590d296362be20f607282686e18df73e1bb07aa37459431d7ec1f74ff6611497811da974b7eb62cd791536268018460d9171eb65ed958af6f12f668b3ae2a8 SHA512 ac0a067320d4dc236d97a69a3019cf01ce87efe2cb98e758f516f90986352fe87d03bfa497d66a2a75e61152a35fd8fac827bafd926d6bd84c8f0d2366e5beb7
+DIST humanize-4.2.1.tar.gz 75327 BLAKE2B 1c36002a2a5d103bc1dae444d9d8a70c3983c778674d5c6aa3a76aa82dc9bd3bf39faefd1c3dcf8d0726b151dfb4f8d8247bb88fdc9af765f703edfb08226b8a SHA512 c84f797b01bb8bcc2e036496f0b727f9c21fe88148a6d90f73ddacd25f73059a46bbc60ef8c3bb81554db0c75f1ab9aa1e551d8473aecb40761e51b59580092a
diff --git a/dev-python/humanize/humanize-4.2.1.ebuild b/dev-python/humanize/humanize-4.2.1.ebuild
new file mode 100644
index 000000000000..c95640b18f8b
--- /dev/null
+++ b/dev-python/humanize/humanize-4.2.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Common humanization utilities"
+HOMEPAGE="
+ https://github.com/python-humanize/humanize/
+ https://pypi.org/project/humanize/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/freezegun[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index e041fb85ae87..adc57809455b 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -2,4 +2,5 @@ DIST hypothesis-hypothesis-python-6.46.11.gh.tar.gz 9312248 BLAKE2B 78b5ca5bd38b
DIST hypothesis-hypothesis-python-6.47.1.gh.tar.gz 9314265 BLAKE2B c2ad0120ab2cbd565f73d472f0a5a87e4b51ff9cf7c08d75dbc54223ad9fe60ed475577ca7dced64ab02d4cc1ee5d30525677c4acfe720af8251f804e72a3b00 SHA512 1aea9f949242d3a273584cd92e1829654d6ce385efcd631b412374f1f9252d3b759b8e216aaa9a49e26e0c3b12673348eac79d0189881f6a811f11daf14b0873
DIST hypothesis-hypothesis-python-6.47.2.gh.tar.gz 9314053 BLAKE2B df607e7d81a280d916cc3946c71f6b2a6c7004263069e83d2647222730d11276b6c246fedbb07c5a4f3c526df38d6ea5c7999bdb416f0c86b0877d0231418c73 SHA512 b58835fac221353ea9beff227dda81f7776e2b50f6a765e536c83bea129d5c5a862551423d9df5abbc0cf294b358c6c537c62add69b3d5a1f38b22e179d2f83c
DIST hypothesis-hypothesis-python-6.47.3.gh.tar.gz 9314739 BLAKE2B 282b012e020fc6494b628ba629c576f604db831c219878ab92539fbd1d980f3363e490ef35f888b68902661dd82e682393641d13a882c1177d8570ec232b217a SHA512 c7231ff06ae5846f718e76c48ed4bb8a1fc0f9aff80c7ddd1ff0ead219eb93dcc7f9d5c5e591390661e81a33bcac79773ea620cfe3f246210114635f0c089144
+DIST hypothesis-hypothesis-python-6.47.4.gh.tar.gz 9314838 BLAKE2B 183048d7d784f8e64bcac1f5bb53b6b9f945b38d555aebd84d0966bcf64178e952f767dcf63122d9b3e8d41d79034b4b11074335e5dbb7575b5f78e152d05c25 SHA512 17a7388ac03ea9029bc5a90f24aa85c3f825bd04ceee963ff7f144ff675b0465afdd22edc5608931f1fd60e83c59d10be24dd74ed64015f942c3f09956b652d7
DIST hypothesis-python-6.46.9.tar.gz 9311955 BLAKE2B f8cf7e216650401ea8a9b427311d10bc65a21b79eb231864c4ff429baea4600f8d84b05e4b94120551ebe17f1b4b99a65e76157efe9d0a133ad68c22b1c46452 SHA512 e4fed5210ba11977958d4d14f9fb32427b812ea7903f391bbf977ade7ae268770e846b0cd2193585f519a02681e4fabfead23eea5bcededaccc0e7a9857e98cf
diff --git a/dev-python/hypothesis/hypothesis-6.47.4.ebuild b/dev-python/hypothesis/hypothesis-6.47.4.ebuild
new file mode 100644
index 000000000000..fd110a80bfde
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.47.4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{8..10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+ https://github.com/HypothesisWorks/hypothesis/
+ https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+ https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ >=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ ' 3.8 3.9 3.10)
+ cli? (
+ $(python_gen_cond_dep '
+ dev-python/black[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ ' "${CLI_COMPAT[@]}")
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ # subtests are broken by warnings from random plugins
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+ epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
+}
+
+python_install() {
+ distutils-r1_python_install
+ if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+ rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+ fi
+}
+
+pkg_postinst() {
+ optfeature "datetime support" dev-python/pytz
+ optfeature "dateutil support" dev-python/python-dateutil
+ optfeature "numpy support" dev-python/numpy
+ optfeature "django support" dev-python/django dev-python/pytz
+ optfeature "pandas support" dev-python/pandas
+ optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/jupyter_server/Manifest b/dev-python/jupyter_server/Manifest
index d713fbdbba40..241fe77a0b23 100644
--- a/dev-python/jupyter_server/Manifest
+++ b/dev-python/jupyter_server/Manifest
@@ -1,2 +1,3 @@
DIST jupyter_server-1.17.0.tar.gz 445648 BLAKE2B d7e19804b6b4cccb72c0a24febe8702829c2a32768e916a9da09ee9f55a08e360cf2a81c3c4bc535ff342c916155bc0b7933a9b5b49645db2b5f9a58ec02ab3a SHA512 d99d4036698d6f8d5e1258de214e3cbc6239b978314af4af7e722789c950edb1f261b98e666cffb46efdfe97a23c001784cfd29d7bf75c02dae53c2c07476b7f
DIST jupyter_server-1.17.1.tar.gz 449682 BLAKE2B ca7a8b57c50a552c20e3c2a6a1318357df87027770bb0f37ee5c6c8db1a99116429ace7f7a28fca9f62728ba8469ce9875dc6f3a4cdf0a447ea8df616dff936f SHA512 bf37188a796e590340589414361e04c8e0f5f81d0e03cf55ad12ef7b59f35708996664da27727824424dadc038b44259a66e55f99c2da4270e727eae615f4e26
+DIST jupyter_server-1.18.0.tar.gz 450132 BLAKE2B a378ba3bfdc629d05478c33365b2d6df893b9ce1dc3ce26c78efcbd69b42441ff730ca58a83fb87446d073f849ce5a6c725784a15953fe9bdae119e529fe30c8 SHA512 5a194a9811162774990b125020d75c134ca32ab916c046cf0345a3959868ab7b293c0659bd54c2da91ef5e8bbb9b433f9a6c16d829277d0f34e924c6332fa6c0
diff --git a/dev-python/jupyter_server/jupyter_server-1.18.0.ebuild b/dev-python/jupyter_server/jupyter_server-1.18.0.ebuild
new file mode 100644
index 000000000000..bf45a2b4a1cf
--- /dev/null
+++ b/dev-python/jupyter_server/jupyter_server-1.18.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=jupyter
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+ <dev-python/anyio-4[${PYTHON_USEDEP}]
+ dev-python/argon2-cffi[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ >=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+ >=dev-python/jupyter_core-4.7.0[${PYTHON_USEDEP}]
+ >=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
+ >=dev-python/nbformat-5.2.0[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ dev-python/prometheus_client[${PYTHON_USEDEP}]
+ >=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+ dev-python/send2trash[${PYTHON_USEDEP}]
+ >=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+ >=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+ >=dev-python/traitlets-5.1[${PYTHON_USEDEP}]
+ dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/ipykernel[${PYTHON_USEDEP}]
+ dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs/source \
+ dev-python/pydata-sphinx-theme \
+ dev-python/myst_parser \
+ dev-python/ipython \
+ dev-python/sphinxemoji \
+ dev-python/sphinxcontrib-github-alt \
+ dev-python/sphinxcontrib-openapi
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+ # This fails if your terminal is zsh (and maybe other non-bash as well?)
+ tests/test_terminal.py::test_culling
+ tests/test_terminal.py::test_terminal_create_with_cwd
+ tests/test_terminal.py::test_terminal_create_with_relative_cwd
+)
+
+src_prepare() {
+ # disable npm use
+ sed -i -e '/\[tool\.jupyter-packaging\.builder\]/,+1d' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest \
+ -p pytest_tornasync.plugin \
+ -p jupyter_server.pytest_plugin \
+ -p pytest_console_scripts \
+ -p pytest_timeout
+}
diff --git a/dev-python/nuitka/Manifest b/dev-python/nuitka/Manifest
index abbd087e1bd3..59a5623cccf4 100644
--- a/dev-python/nuitka/Manifest
+++ b/dev-python/nuitka/Manifest
@@ -1 +1,2 @@
DIST Nuitka-0.8.4.tar.gz 3828278 BLAKE2B dbd6abb945f66ab6a5a359b8370fd3d5d36fbdc2c232b5002356f59ffbfa531180b96467b67a2edbb7a779c75ebe58789e9ae0ff806b5649eea4a5b7d9c0934c SHA512 683918e60f2f65d22911f894c2e4fedeafd9d0ef0cacd48bb66422fa2077f225c7c861186b83b9c0fd50eb965b956a1b26342249b3db2af599250c16fe84a152
+DIST Nuitka-0.9.tar.gz 3855240 BLAKE2B 59a508aabb04af0b841879a4de23fe9f9f8ea2588125127834319da21ef22ab530d8e39a2baba1b49043e9997dff9a20004fc548af5b09456b5eb3cd8f1d30a8 SHA512 ae2903e89233b7944e1ee1aa846897d30c352302bb8b064a31ab69237dc15ed0e451bba63db5530968e10f60b8da745bf7d7f1f130ff039d9aac2329f628f32f
diff --git a/dev-python/nuitka/nuitka-0.9.ebuild b/dev-python/nuitka/nuitka-0.9.ebuild
new file mode 100644
index 000000000000..3574a8ce15f5
--- /dev/null
+++ b/dev-python/nuitka/nuitka-0.9.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 flag-o-matic optfeature
+
+DESCRIPTION="Python to native compiler"
+HOMEPAGE="https://www.nuitka.net"
+SRC_URI="https://nuitka.net/releases/${P^}.tar.gz"
+S="${WORKDIR}/${P^}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-util/scons[${PYTHON_USEDEP}]"
+BDEPEND="
+ ${RDEPEND}
+ test? ( dev-util/ccache )
+"
+
+DOCS=( Changelog.pdf Developer_Manual.pdf README.pdf )
+
+distutils-r1_src_prepare() {
+ # remove vendored version of SCons that is Python2 only
+ # this should be removed when upstream removes support for Python2
+ rm -vR "${PN}/build/inline_copy/lib/scons-2.3.2/SCons" || die
+ eapply_user
+}
+
+python_install() {
+ distutils-r1_python_install
+ doman doc/nuitka3.1 doc/nuitka3-run.1
+}
+
+python_test() {
+ append-ldflags -Wl,--no-warn-search-mismatch
+ ./tests/basics/run_all.py search || die
+}
+
+pkg_postinst() {
+ optfeature "support for stand-alone executables" app-admin/chrpath
+}
diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 0154c9389355..85b8cf5356bf 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1,2 +1,3 @@
DIST oslo.utils-4.13.0.tar.gz 101834 BLAKE2B 9d3457ee9ce1746869120bf66d83495b4e1f2b4ca005285fa121ff4c176e85148662cd1de52bdaf93dc18d85478f2cbfde9b310e748b895f01c77ef82019dc0e SHA512 1d97fdaab79cc6c4cc34efdafca7263a2679e60d446aadc46fe31d7fdda2051b37f9df79d149644d914c7274e7fa2d9ef6a1c1aeafad8a1333221dcbe65f4723
DIST oslo.utils-5.0.0.tar.gz 101823 BLAKE2B be62ddc2fb9130e3f678366b6181f1f334f95846a09ede4a08917cd88427492978e53039a482a7158f234caf96c9e520026ab6009f1df5de588a9fe68aa0664f SHA512 8941caf086354c9066ef51e64dcab5854b8d99c2b51807cb2d8b75fac0983f5787e499b0727423b624791ead2b5c9b55b463d5ff47f7586f3e302dccec1f5408
+DIST oslo.utils-6.0.0.tar.gz 101261 BLAKE2B 8a659b4bedf49e40c85ee40fe026205964d2f4a919170e4700c85e754f4bbffdf5bb9305aea00f7b36233feec93e42bf5e0c72591eeedc02709a7fcdba64d9b6 SHA512 9f9dcd585419372711af69917daf717d7c694cc604aed4db242e508ca6bdea3db9a52a29c354dbb5c80473a819c80dec9eccad7e6f6ca297c3469bcd2db5c7d5
diff --git a/dev-python/oslo-utils/oslo-utils-6.0.0.ebuild b/dev-python/oslo-utils/oslo-utils-6.0.0.ebuild
new file mode 100644
index 000000000000..7af52e60063d
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-6.0.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+ >=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+ >=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+ >=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+ >=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+ >=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+ >=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+ >=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+ >=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/eventlet-0.23.0[${PYTHON_USEDEP}]
+ ' python3_{8..9})
+ >=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+ >=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+ >=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+ >=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+ # spurious rdep
+ sed -i -e '/pbr/d' requirements.txt || die
+ distutils-r1_src_prepare
+}
+
+python_compile() {
+ distutils-r1_python_compile
+ if ! has "${EPYTHON}" python3.{8..9}; then
+ find "${BUILD_DIR}"/install -name '*eventletutils*.py' -delete || die
+ fi
+}
+
+python_test() {
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ eunittest
+}
diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index e22879384dff..657b035e520b 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1 +1,2 @@
DIST pandas-1.4.2.tar.gz 4940242 BLAKE2B b44c9e46458b4e2919b2d215c8678601ef0976118197172ddc74fa712cf07b02cdb09b79940e90bf6907a45e7e3c63615292f7141a4fb8ed4ae22a36decd1e39 SHA512 6406241e30e9ed386610dd90bbb7407cfe3e94ff20c8fd1241aa75288894666f06e59f7c74b5f916080a3745254ba22ec9dad1195f040b613639b5712aced571
+DIST pandas-1.4.3.tar.gz 4941520 BLAKE2B b134f7c04c2478b7105214ed62e9adcaed98ffb4179a785f7887850d66702bf0f185d60a3da6de6226742529008bac614b494453dca929e477960ff3b43ef93d SHA512 d8d7575ce2b813361641d4e438844e03ed79179f5dcc56f2e4923bfeceab6f825a9bcc419e9492ee5e0272ea7c9bb9eeab6a0e242a880a87999df2a492436d8e
diff --git a/dev-python/pandas/pandas-1.4.3.ebuild b/dev-python/pandas/pandas-1.4.3.ebuild
new file mode 100644
index 000000000000..f7a9875c44b8
--- /dev/null
+++ b/dev-python/pandas/pandas-1.4.3.ebuild
@@ -0,0 +1,197 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="https://pandas.pydata.org/
+ https://github.com/pandas-dev/pandas/"
+SRC_URI="
+ https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz
+"
+S="${WORKDIR}/${P/_/}"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+ >=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+ >=dev-python/numexpr-2.7.0[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+OPTIONAL_DEPEND="
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/blosc[${PYTHON_USEDEP}]
+ || (
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ )
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ || (
+ dev-python/openpyxl[${PYTHON_USEDEP}]
+ dev-python/xlsxwriter[${PYTHON_USEDEP}]
+ )
+ >=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+ >=dev-python/xarray-0.12.3[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+ >=dev-python/xlrd-1.2.0[${PYTHON_USEDEP}]
+ >=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+ !hppa? (
+ dev-python/statsmodels[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+ )
+ X? (
+ || (
+ dev-python/PyQt5[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ x11-misc/xsel
+ )
+ )
+"
+COMMON_DEPEND="
+ >=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.8.1-r3[${PYTHON_USEDEP}]
+ >=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+ ${COMMON_DEPEND}
+ >=dev-python/cython-0.29.24[${PYTHON_USEDEP}]
+ doc? (
+ ${VIRTUALX_DEPEND}
+ app-text/pandoc
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/ipython[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ dev-python/nbsphinx[${PYTHON_USEDEP}]
+ >=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+ >=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+ >=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/rpy[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/xlrd[${PYTHON_USEDEP}]
+ dev-python/xlwt[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ )
+ test? (
+ ${VIRTUALX_DEPEND}
+ ${RECOMMENDED_DEPEND}
+ ${OPTIONAL_DEPEND}
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-5.5.3[${PYTHON_USEDEP}]
+ dev-python/openpyxl[${PYTHON_USEDEP}]
+ dev-python/pymysql[${PYTHON_USEDEP}]
+ >=dev-python/pytest-6[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-1.31[${PYTHON_USEDEP}]
+ dev-python/psycopg:2[${PYTHON_USEDEP}]
+ dev-python/xlsxwriter[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ x11-misc/xsel
+ )
+"
+# dev-python/statsmodels invokes a circular dep
+# hence rm from doc? ( ), again
+RDEPEND="
+ ${COMMON_DEPEND}
+ !minimal? ( ${RECOMMENDED_DEPEND} )
+ full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+ # Prevent un-needed download during build
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" \
+ -i doc/source/conf.py || die
+
+ # requires package installed
+ sed -e '/extra_compile_args =/s:"-Werror"::' \
+ -i setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile() {
+ distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+ # To build docs the need be located in $BUILD_DIR,
+ # else PYTHONPATH points to unusable modules.
+ if use doc; then
+ cd "${BUILD_DIR}"/lib || die
+ cp -ar "${S}"/doc . && cd doc || die
+ LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+ fi
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # test for rounding errors, fails if we have better precision
+ # e.g. on amd64 with FMA or on arm64
+ # https://github.com/pandas-dev/pandas/issues/38921
+ pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+ # TODO
+ pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated
+ pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated_direct
+
+ # TODO: these require a running db server
+ pandas/tests/io/test_sql.py::TestMySQLAlchemy
+ pandas/tests/io/test_sql.py::TestMySQLAlchemyConn
+ pandas/tests/io/test_sql.py::TestPostgreSQLAlchemy
+ pandas/tests/io/test_sql.py::TestPostgreSQLAlchemyConn
+ )
+
+ local -x LC_ALL=C.UTF-8
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ "${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+ epytest pandas --skip-slow --skip-network -m "not single" \
+ -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
+ die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use doc; then
+ dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+ einfo "An initial build of docs is absent of references to statsmodels"
+ einfo "due to circular dependency. To have them included, emerge"
+ einfo "statsmodels next and re-emerge pandas with USE doc"
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+ optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+ optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
+ optfeature "for msgpack compression using blosc" dev-python/blosc
+ optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+ optfeature "Plotting support" dev-python/matplotlib
+ optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.0" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+ optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+ optfeature "R I/O support" dev-python/rpy
+ optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+ optfeature "SQL database support" ">=dev-python/sqlalchemy-1.3.0"
+ optfeature "miscellaneous statistical functions" dev-python/scipy
+ optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}
diff --git a/dev-python/pycson/pycson-0.8-r3.ebuild b/dev-python/pycson/pycson-0.8-r3.ebuild
index aaaa1a6d6df1..9613bf7b8c0a 100644
--- a/dev-python/pycson/pycson-0.8-r3.ebuild
+++ b/dev-python/pycson/pycson-0.8-r3.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/avakar/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
-KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+KEYWORDS="amd64 ~ppc ~riscv x86"
RDEPEND="dev-python/speg[${PYTHON_USEDEP}]"
diff --git a/dev-python/speg/speg-0.3-r3.ebuild b/dev-python/speg/speg-0.3-r3.ebuild
index 8c46c6607e42..bd1a0590f539 100644
--- a/dev-python/speg/speg-0.3-r3.ebuild
+++ b/dev-python/speg/speg-0.3-r3.ebuild
@@ -9,6 +9,6 @@ HOMEPAGE="https://github.com/avakar/speg/"
SRC_URI="https://github.com/avakar/speg/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SLOT="0"
LICENSE="MIT"
-KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+KEYWORDS="amd64 ~ppc ~riscv x86"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
RDEPEND=""
diff --git a/dev-python/sqlalchemy/Manifest b/dev-python/sqlalchemy/Manifest
index d6c5b87b467c..8fe3b9337dd7 100644
--- a/dev-python/sqlalchemy/Manifest
+++ b/dev-python/sqlalchemy/Manifest
@@ -1,2 +1,3 @@
DIST SQLAlchemy-1.4.36.tar.gz 8146415 BLAKE2B 62560ac2f2c542d60588a24eef225d39f1b6c4cf6feddfac4631e06731206a837cc0f76b88b40c73600361243857e9e1768b4b4ac0bf5ee8e28736d81028ae58 SHA512 c9bb38ce5eeb7817727e93695f10cf5c247710b809f3298b233ed8be4e2cc08e5a14581d0c5aa2af02d7a49f036fe3a0bb7a88120b58bdce0f115016bdaf2c77
DIST SQLAlchemy-1.4.37.tar.gz 8155965 BLAKE2B cf21c2ab73a5ba2576a857a12f30ea516265af946e25c1b137e57019d862bf04f4757b4755cee28e6f53642d1f1b58f43c99cd1c69f87640e47ac8a1d1ff8d28 SHA512 3f8a814f9bb6fa273f7b210c4567bf7411d0cf2e5caf010a5387fb946063704c342072145a858fb906545dfb1b959155d041e6073273674e51715356fc1f39e6
+DIST SQLAlchemy-1.4.38.tar.gz 8211925 BLAKE2B c65a8bddfc77bb6262e24a9b191344da312641dcd759de8541439e13cc532d9c2ef92da50c0b46ace60f2fd8582dfa6ea37b2f393fd979b3f122d962c688ede8 SHA512 4f54873fe2ba14b00cfa900251bc81d4fbbd62ed2b0f5f35bd3d5157796b869a3b7a9acf162f65da3f05b4b43cfc8bba437600f7fb81887a1839043a6ad516b4
diff --git a/dev-python/sqlalchemy/sqlalchemy-1.4.38.ebuild b/dev-python/sqlalchemy/sqlalchemy-1.4.38.ebuild
new file mode 100644
index 000000000000..6e9d2ad0a598
--- /dev/null
+++ b/dev-python/sqlalchemy/sqlalchemy-1.4.38.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="sqlite?"
+
+inherit distutils-r1 optfeature
+
+MY_PN="SQLAlchemy"
+MY_P="${MY_PN}-${PV/_beta/b}"
+
+DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
+HOMEPAGE="
+ https://www.sqlalchemy.org/
+ https://pypi.org/project/SQLAlchemy/
+ https://github.com/sqlalchemy/sqlalchemy/
+"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="examples +sqlite test"
+
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+ # hardcode call counts specific to Python versions
+ test/aaa_profiling
+)
+
+src_prepare() {
+ sed -i -e '/greenlet/d' setup.cfg || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # warning tests are unreliable
+ test/base/test_warnings.py
+ )
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ test/ext/test_associationproxy.py::ProxyHybridTest::test_msg_fails_on_cls_access
+ )
+ if ! has_version "dev-python/greenlet[${PYTHON_USEDEP}]"; then
+ EPYTEST_DESELECT+=(
+ test/ext/asyncio/test_engine_py3k.py::TextSyncDBAPI::test_sync_driver_execution
+ test/ext/asyncio/test_engine_py3k.py::TextSyncDBAPI::test_sync_driver_run_sync
+ "test/engine/test_pool.py::PoolEventsTest::test_checkin_event_gc[True-_exclusions0]"
+ "test/engine/test_pool.py::QueuePoolTest::test_userspace_disconnectionerror_weakref_finalizer[True-_exclusions0]"
+ )
+ fi
+
+ # upstream's test suite is horribly hacky; it relies on disabling
+ # the warnings plugin and turning warnings into errors; this also
+ # means that any DeprecationWarnings from third-party plugins cause
+ # everything to explode
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=
+ # upstream automagically depends on xdist when it is importable
+ if has_version "dev-python/pytest-xdist[${PYTHON_USEDEP}]"; then
+ PYTEST_PLUGINS+=xdist.plugin
+ fi
+ epytest
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ dodoc -r examples
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "asyncio support" dev-python/greenlet
+ optfeature "MySQL support" \
+ dev-python/mysqlclient \
+ dev-python/pymysql \
+ dev-python/mysql-connector-python
+ optfeature "postgresql support" dev-python/psycopg:2
+}
diff --git a/dev-python/uvicorn/Manifest b/dev-python/uvicorn/Manifest
index db661330a4fa..6d256308a808 100644
--- a/dev-python/uvicorn/Manifest
+++ b/dev-python/uvicorn/Manifest
@@ -1 +1,2 @@
DIST uvicorn-0.17.6.tar.gz 708048 BLAKE2B 83b06907c8109b38e13930d8b73584682fa4e34fe7e51fe14b6ca1ddc7ef8122d950a09e31cb364a02f5f12eead5d0522b41cbf428509c6900604d4e2776dfb2 SHA512 d5c5223759d59648f279e22f7e6af728fe8117ed75488d125c1db3e5e9d385a50d574cff72ac46db4eb0a78d0e4f690096cfe78c774674dfba61860e55b7494e
+DIST uvicorn-0.18.1.gh.tar.gz 712588 BLAKE2B f99c173015d3efdd6f7d6257384045542cbf95ab65fdd84f47ee5df4677865d0b4d6de5f23db0bc2713cb286242a029b056c4076268b14d238a3e9f57c02fc42 SHA512 d8650ace78d19c44d03de8413bf06b2dd3208c7e47c4d9e17ecbed99eef938ec08eb249b204713139b985ae4b117c7da64836c25bf8d20610363bedcf1ebf990
diff --git a/dev-python/uvicorn/uvicorn-0.18.1.ebuild b/dev-python/uvicorn/uvicorn-0.18.1.ebuild
new file mode 100644
index 000000000000..fdb0439c9c98
--- /dev/null
+++ b/dev-python/uvicorn/uvicorn-0.18.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Lightning-fast ASGI server implementation"
+HOMEPAGE="https://www.uvicorn.org/"
+SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/asgiref-3.4.0[${PYTHON_USEDEP}]
+ >=dev-python/click-7.0[${PYTHON_USEDEP}]
+ >=dev-python/h11-0.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/httpx[${PYTHON_USEDEP}]
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/python-dotenv[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ >=dev-python/websockets-10.0[${PYTHON_USEDEP}]
+ dev-python/wsproto[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+ # too long path for unix socket
+ tests/test_config.py::test_bind_unix_socket_works_with_reload_or_workers
+ # need unpackaged httptools
+ "tests/middleware/test_logging.py::test_trace_logging_on_http_protocol[httptools]"
+ tests/protocols/test_http.py::test_fragmentation
+)
+
+EPYTEST_IGNORE=(
+ # needs watchfiles, which in turn needs maturin, which needs rust
+ tests/supervisors/test_reload.py
+)
+
+pkg_postinst() {
+ optfeature "auto reload on file changes" dev-python/watchfiles
+}
generated by cgit v1.3.1 (git 2.54.0) at 2026-06-02 22:01:32 +0000