1 files changed, 41 insertions, 0 deletions
diff --git a/dev-python/typeguard/typeguard-4.5.1.ebuild b/dev-python/typeguard/typeguard-4.5.1.ebuild
new file mode 100644
index 000000000000..875438033cd4
--- /dev/null
+++ b/dev-python/typeguard/typeguard-4.5.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/agronholm/typeguard
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Run-time type checker for Python"
+HOMEPAGE="
+	https://pypi.org/project/typeguard/
+	https://github.com/agronholm/typeguard/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.14.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6.4[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# mypy changes results from version to version
+		tests/mypy
+	)
+
+	local -x PYTHONDONTWRITEBYTECODE=
+	# the XFAIL test pass due to some package being installed
+	epytest -o xfail_strict=False -p typeguard
+}