3 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/trakit/Manifest b/dev-python/trakit/Manifest
new file mode 100644
index 000000000000..e2bcb274fab0
--- /dev/null
+++ b/dev-python/trakit/Manifest
@@ -0,0 +1 @@
+DIST trakit-0.2.5.tar.gz 34873 BLAKE2B 5e5272a7a9882328dd1f5fc2a8e142511d0a1cb19d488378b9fa43772ee77ce787d309d0b10fe77ee8f737817e41c8fdf6cc2d8eaafa989353706cbc92358e89 SHA512 95dfd06d8cb6c9f4b2f1412c4b505209e5122595f0ebba1b6bef9ecb80c31e4f8a4b7aba706931ce9684f2e8ddf4f9836c9f034053ce2f25c857d08c76a9eaf1
diff --git a/dev-python/trakit/metadata.xml b/dev-python/trakit/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/trakit/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/trakit/trakit-0.2.5.ebuild b/dev-python/trakit/trakit-0.2.5.ebuild
new file mode 100644
index 000000000000..8383110fc182
--- /dev/null
+++ b/dev-python/trakit/trakit-0.2.5.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Guess additional information from titles in media tracks"
+HOMEPAGE="
+	https://github.com/ratoaq2/trakit/
+	https://pypi.org/project/trakit/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/babelfish-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.2[${PYTHON_USEDEP}]
+	>=dev-python/rebulk-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/unidecode-1.3.6[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Network
+	tests/test_generate.py::test_generate_config
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# sigh, poetry
+	sed -i -e 's:\^:>=:' pyproject.toml || die
+}