2 files changed, 70 insertions, 0 deletions
diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index 94410c03021a..1f44bc52c64e 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1 +1,2 @@
 DIST tavern-2.15.0.gh.tar.gz 240494 BLAKE2B df6876138aa661ff4298b00315eef7b75050e24c076f2c33fad55c3c096d8e4593ae396ddfc29fb09e673e56fb2a708b1c16922b85cee272ba8699d1e63603a8 SHA512 b39ee0150cd631ee33132b91cf1c480f0c5c3afb6a7573f3fba3cb59257e61a0a90eee1b05c3e048e33e8646cd16e9300ae2fe4f7f2dbeda32a5cfc0c3c2c575
+DIST tavern-2.16.0.gh.tar.gz 241605 BLAKE2B 1c813c80de9680f700668200961a0cbe3a16c0fc9e169fa32724c35ff518e9b337639f493c586bd23f42aa1cff1fcbca64fac8807a1cdb0925c61a738450f736 SHA512 9bf582e2f118630bd036dcf726fafe4a79092981e77631e82e9be3f1504d73f68bf650be2fb815412e2dc1fc4ab63587801bff646dcc4dd503415c139f47f3d7
diff --git a/dev-python/tavern/tavern-2.16.0.ebuild b/dev-python/tavern/tavern-2.16.0.ebuild
new file mode 100644
index 000000000000..876b69648246
--- /dev/null
+++ b/dev-python/tavern/tavern-2.16.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+	>=dev-python/paho-mqtt-1.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7[${PYTHON_USEDEP}]
+	>=dev-python/python-box-6[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/simpleeval-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/faker[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires grpc
+		tests/unit/test_extensions.py::TestGrpcCodes
+		# broken with paho-mqtt-2
+		tests/unit/test_mqtt.py::TestClient::test_context_connection_success
+	)
+	local EPYTEST_IGNORE=(
+		# require grpc*
+		tavern/_plugins/grpc
+		tests/unit/tavern_grpc
+	)
+
+	local EPYTEST_PLUGINS=( tavern )
+	epytest
+}