3 files changed, 103 insertions, 0 deletions
diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
new file mode 100644
index 000000000000..78fad56f7639
--- /dev/null
+++ b/dev-python/statsmodels/Manifest
@@ -0,0 +1 @@
+DIST statsmodels-0.14.6.tar.gz 20689085 BLAKE2B fc6fe72d2f4016add10b25fb6aee7fe6a24187e4156534d7ae309c7f0b596b025b093ef45ad3201055a00361be4b8f42ba57dd0684efda8e01f6899b7ade3254 SHA512 5bb28aea779236d5f48743db624c048f78117456e1752414bd156f650098a996a81d882fd271fc5e203298dc941a656450f252a94b2d05e86b571e5ebb0b29fd
diff --git a/dev-python/statsmodels/metadata.xml b/dev-python/statsmodels/metadata.xml
new file mode 100644
index 000000000000..d65f1c87ee9f
--- /dev/null
+++ b/dev-python/statsmodels/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci-mathematics@gentoo.org</email>
+    <name>Gentoo Mathematics Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    statsmodels is a Python module that allows users to explore data,
+    estimate statistical models, and perform statistical tests. An
+    extensive list of descriptive statistics, statistical tests,
+    plotting functions, and result statistics are available for
+    different types of data and each estimator. Researchers across
+    fields may find that statsmodels fully meets their needs for
+    statistical computing and data analysis in Python.
+  </longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/statsmodels/statsmodels-0.14.6.ebuild b/dev-python/statsmodels/statsmodels-0.14.6.ebuild
new file mode 100644
index 000000000000..327b0efc05e2
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.14.6.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="
+	https://www.statsmodels.org/stable/index.html
+	https://github.com/statsmodels/statsmodels/
+	https://pypi.org/project/statsmodels/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~riscv ~x86"
+IUSE="examples"
+
+# NB: upstream requires building with numpy-2 but supports 1.x
+# at runtime
+DEPEND="
+	>=dev-python/numpy-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/numpy-1.22.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.4[${PYTHON_USEDEP}]
+	>=dev-python/patsy-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter-client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest statsmodels
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}