1 files changed, 38 insertions, 0 deletions
diff --git a/dev-python/simplejson/simplejson-4.1.2.ebuild b/dev-python/simplejson/simplejson-4.1.2.ebuild
new file mode 100644
index 000000000000..06c01858aff7
--- /dev/null
+++ b/dev-python/simplejson/simplejson-4.1.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/simplejson/simplejson
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, fast, extensible JSON encoder/decoder for Python"
+HOMEPAGE="
+	https://github.com/simplejson/simplejson/
+	https://pypi.org/project/simplejson/
+"
+
+LICENSE="|| ( MIT AFL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="+native-extensions"
+
+DOCS=( README.rst CHANGES.txt )
+
+distutils_enable_tests unittest
+
+src_configure() {
+	# native-extensions are always disabled on PyPy
+	# https://github.com/simplejson/simplejson/blob/master/setup.py#L121
+	export DISABLE_SPEEDUPS=$(usex native-extensions 0 1)
+	use native-extensions && export REQUIRE_SPEEDUPS=1
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}