3 files changed, 65 insertions, 0 deletions
diff --git a/dev-python/pyu2f/Manifest b/dev-python/pyu2f/Manifest
new file mode 100644
index 000000000000..1d88c564bc49
--- /dev/null
+++ b/dev-python/pyu2f/Manifest
@@ -0,0 +1 @@
+DIST pyu2f-0.1.5.gh.tar.gz 39008 BLAKE2B 475a47ad99bfbe8f85ebe246eb7c394d0855732fc6bf0dd887bb32ad02bacb1f34dadc5506d330add64bca5b353824e773d2b1e971e78d9cf9dc2438d12b4f62 SHA512 ddb15bb1d917117a2b19ad169ac0f8b8c7667d7ef8ee4c266cc30326429bb3627d41d84dc390ce0036d0b0f110e1d2da47d06d4e4d03a8be98cedb5ea3112246
diff --git a/dev-python/pyu2f/metadata.xml b/dev-python/pyu2f/metadata.xml
new file mode 100644
index 000000000000..591131b1265f
--- /dev/null
+++ b/dev-python/pyu2f/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>zmedico@gentoo.org</email>
+    <name>Zac Medico</name>
+  </maintainer>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pyu2f/pyu2f-0.1.5-r1.ebuild b/dev-python/pyu2f/pyu2f-0.1.5-r1.ebuild
new file mode 100644
index 000000000000..fa07b5c9ba78
--- /dev/null
+++ b/dev-python/pyu2f/pyu2f-0.1.5-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python based U2F host library"
+HOMEPAGE="
+	https://github.com/google/pyu2f/
+	https://pypi.org/project/pyu2f/
+"
+SRC_URI="
+	https://github.com/google/pyu2f/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( CONTRIBUTING.md README.md )
+
+EPYTEST_PLUGINS=( pyfakefs )
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# https://github.com/google/pyu2f/commit/5e2f862dd5ba61eadff341dbf0a1202e91b1b145
+	sed -i -e 's:logger[.]warn:&ing:' pyu2f/hid/macos.py || die
+	sed -e "s:CreateFile:create_file:" \
+		-e "s:CreateDirectory:create_dir:" \
+		-e "s:RemoveObject:remove_object:" \
+		-e "s:SetContents:set_contents:" \
+		-i pyu2f/tests/hid/linux_test.py || die
+	# https://github.com/google/pyu2f/commit/793acd9ff6612bb035f0724b04e10a01cdb5bb8d
+	# https://github.com/google/pyu2f/commit/dad654010a030f1038bd2df95a9647fb417e0447
+	find pyu2f/tests -name '*.py' -exec \
+		sed -e 's:assertEquals:assertEqual:' \
+			-e 's:assertRaisesRegexp:assertRaisesRegex:' \
+			-i {} + || die
+	distutils-r1_python_prepare_all
+}