2 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/pyproj/Manifest b/dev-python/pyproj/Manifest
index be235bf1c216..43bfc94e36e5 100644
--- a/dev-python/pyproj/Manifest
+++ b/dev-python/pyproj/Manifest
@@ -1 +1,2 @@
 DIST pyproj-3.6.0.gh.tar.gz 238966 BLAKE2B 441904a343b7abab19e9d17a1bcb053d4f5606886b1325cfadcdd8456b61871bee4d13c49802008aea5c5864c40ef15a4a7681969890368a1991ba696b76ab78 SHA512 e713de94331022112049e76f7f56d24439a0dee339e8419acf8b023b3234a7c2ba468bed880749036fca2a93b289575ebb74854ba178f3b6debae8aa53befcf7
+DIST pyproj-3.6.1.gh.tar.gz 239568 BLAKE2B e396e7c13dfc90f8a8eaf93b7bc0e62921779930d9c42b21ce8afa95597b13e527c179096600f40140d6d00d0f425580fccc34ae55a4e8c985d1b618554c9db4 SHA512 19c55e7ab99aae70bc318246146dc98ba75cc4884de798392f590df48c6a83e1b80504fd9c555ffd9d19262eb93cdf2c46e4805a3ae6dc07b3eaa4669f025ff0
diff --git a/dev-python/pyproj/pyproj-3.6.1.ebuild b/dev-python/pyproj/pyproj-3.6.1.ebuild
new file mode 100644
index 000000000000..9591127e7cf0
--- /dev/null
+++ b/dev-python/pyproj/pyproj-3.6.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to the PROJ library"
+HOMEPAGE="
+	https://github.com/pyproj4/pyproj/
+	https://pypi.org/project/pyproj/
+"
+SRC_URI="
+	https://github.com/pyproj4/pyproj/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux"
+
+DEPEND="
+	>=sci-libs/proj-9.0.0:=
+"
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# Avoid greedily trying -L/usr/lib, etc
+	# https://github.com/pyproj4/pyproj/blob/main/setup.py#L76
+	export PROJ_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
+	export PROJ_INCDIR="${ESYSROOT}/usr/include"
+}
+
+python_test() {
+	rm -rf pyproj || die
+	epytest -m "not network" test
+}