2 files changed, 65 insertions, 0 deletions
diff --git a/dev-python/pyopenssl/Manifest b/dev-python/pyopenssl/Manifest
index 59de1cc87588..0ac4f75fbf61 100644
--- a/dev-python/pyopenssl/Manifest
+++ b/dev-python/pyopenssl/Manifest
@@ -1 +1,2 @@
 DIST pyopenssl-25.0.0.tar.gz 179573 BLAKE2B e5c9c9e4daa590008163b2e67b7c318cf72a0c922b1db41bf8ef31a44aa59f98a7a594ce1b59a887d47ffb0257f1d11faa920d3bf7807a19e6ece819947e5614 SHA512 77f9f03610a4ddaf115d581b873e728a79ba0e8d762ddeffacb600b6bc4a50bde2edfc114aebe12b9e177f3d53c19fe0c2bf0a5821e609489b8640e23c324376
+DIST pyopenssl-25.1.0.tar.gz 179937 BLAKE2B 4c3f9d70c9e1929ae4af04408f6b20585829ca3cffc08444a1ed615e2a864495a93ed09e46f59b2079e603adf89770a1f540ade336545eb9c139ee0d7ef8340e SHA512 a2783d02011b09669fb215b0ab44d0c91bea10bcd72d6369c4f680768fd9eb9d1b7622566c22cd29fcedacea2b21f60a86311f5cf996d2acea1a4b51cbd82ef1
diff --git a/dev-python/pyopenssl/pyopenssl-25.1.0.ebuild b/dev-python/pyopenssl/pyopenssl-25.1.0.ebuild
new file mode 100644
index 000000000000..a9ead9decf3c
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-25.1.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=pyOpenSSL
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	https://www.pyopenssl.org/
+	https://github.com/pyca/pyopenssl/
+	https://pypi.org/project/pyOpenSSL/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/cryptography-46[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-41.0.5[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.9[${PYTHON_USEDEP}]
+	' 3.{11..12})
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/cffi[${PYTHON_USEDEP}]
+		' 'python*')
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	local -x TZ=UTC
+	local EPYTEST_DESELECT=(
+		tests/test_ssl.py::TestContext::test_set_default_verify_paths
+	)
+
+	if ! tc-has-64bit-time_t; then
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_crypto.py::TestX509StoreContext::test_verify_with_time
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	epytest -p rerunfailures
+}