1 files changed, 86 insertions, 0 deletions
diff --git a/dev-python/pygobject/pygobject-3.58.0.ebuild b/dev-python/pygobject/pygobject-3.58.0.ebuild
new file mode 100644
index 000000000000..044d707349d2
--- /dev/null
+++ b/dev-python/pygobject/pygobject-3.58.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=no
+GNOME_TARBALL_SUFFIX="gz"
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit gnome.org meson virtualx xdg distutils-r1
+
+DESCRIPTION="Python bindings for GObject Introspection"
+HOMEPAGE="
+	https://pygobject.gnome.org/
+	https://gitlab.gnome.org/GNOME/pygobject/
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos ~x64-solaris"
+IUSE="+cairo test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.80:2
+	>=dev-libs/gobject-introspection-1.84:=
+	dev-libs/libffi:=
+	cairo? (
+		>=dev-python/pycairo-1.16.0[${PYTHON_USEDEP}]
+		x11-libs/cairo[glib]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=app-accessibility/at-spi2-core-2.46.0[introspection]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		x11-libs/gdk-pixbuf:2[introspection,jpeg]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+python_configure() {
+	local emesonargs=(
+		$(meson_feature cairo pycairo)
+		$(meson_use test tests)
+		-Dpython="${EPYTHON}"
+	)
+	meson_src_configure
+}
+
+python_compile() {
+	meson_src_compile
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
+	local -x GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x XDG_CACHE_HOME="${T}/${EPYTHON}"
+	local _PYTEST_ADDOPTS=(
+		 # see epytest in python-utils-r1.eclass
+		-vv -ra -l -o filterwarnings=
+		# test_python_calls_sync: timeout
+		--deselect tests/test_gdbus.py::TestGDBusClient::test_python_calls_sync
+		# test_pointer_array_struct_with_guint8: broken on BE but test is dodgy anyway, bug #978759
+		--deselect tests/test_gi.py::TestStructure::test_pointer_array_struct_with_guint8
+	)
+	local -x PYTEST_ADDOPTS="${_PYTEST_ADDOPTS[@]}"
+
+	meson_src_test --timeout-multiplier 3 || die "test for ${EPYTHON}"
+}
+
+python_install() {
+	meson_src_install
+	python_optimize
+}