3 files changed, 99 insertions, 1 deletions
diff --git a/dev-python/pyamg/files/pyamg-5.3.0-backport.patch b/dev-python/pyamg/files/pyamg-5.3.0-backport.patch
new file mode 100644
index 000000000000..b69bc3e2730b
--- /dev/null
+++ b/dev-python/pyamg/files/pyamg-5.3.0-backport.patch
@@ -0,0 +1,36 @@
+From 9f8299bcf1141e627503c3f208eda413bc1e28e6 Mon Sep 17 00:00:00 2001
+From: Stephen Huan <stephen.huan@cgdct.moe>
+Date: Tue, 24 Mar 2026 21:47:30 -0400
+Subject: [PATCH] fix(util/utils): duplicate zeros in filter_operator
+
+The explicit zeros added to A to match C's nonzeros can be redundant
+with the existing entries in A. These duplicate entries are acted on
+independently by amg_core.satisfy_constraints_helper, causing the
+update to effectively happen multiple times when duplicate entries in
+sparse arrays are added together according to scipy's semantics.
+---
+ pyamg/util/utils.py | 4 +++-
+ 1 file changed, 3 insertions(+), 1 deletion(-)
+
+diff --git a/pyamg/util/utils.py b/pyamg/util/utils.py
+index 69ed1507..4a955253 100644
+--- a/pyamg/util/utils.py
++++ b/pyamg/util/utils.py
+@@ -1242,7 +1242,7 @@ def filter_operator(A, C, B, Bf, BtBinv=None):
+     C = C.copy()
+     C.data[:] = 1
+     A = A.multiply(C)
+-    # add explicit zeros to A wherever C is nonzero, but A is zero
++    # add explicit zeros to A wherever C is nonzero
+     A = A.tocoo()
+     C = C.tocoo()
+     A.data = np.hstack((np.zeros(C.data.shape, dtype=A.dtype), A.data))
+@@ -1252,6 +1252,8 @@ def filter_operator(A, C, B, Bf, BtBinv=None):
+         A = A.tobsr((rows_per_block, cols_per_block))
+     else:
+         A = A.tocsr()
++    # eliminate redundant zeros created by the above
++    A.sum_duplicates()
+ 
+     # Calculate difference between A @ B and Bf
+     diff = A @ B - Bf
diff --git a/dev-python/pyamg/pyamg-5.3.0-r1.ebuild b/dev-python/pyamg/pyamg-5.3.0-r1.ebuild
new file mode 100644
index 000000000000..d7ea36861c61
--- /dev/null
+++ b/dev-python/pyamg/pyamg-5.3.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Algebraic multigrid solvers in Python"
+HOMEPAGE="
+	https://github.com/pyamg/pyamg/
+	https://pypi.org/project/pyamg/
+"
+SRC_URI="
+	https://github.com/pyamg/pyamg/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-python/pybind11[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	dev-python/cppheaderparser[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.11.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	>=dev-python/setuptools-scm-7.0.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		# https://github.com/pyamg/pyamg/commit/9f8299bcf1141e627503c3f208eda413bc1e28e6
+		"${FILESDIR}/${P}-backport.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# invalid with >=setuptools-scm-9
+	sed -i -e '/version =/d' setup.cfg || die
+}
+
+python_test() {
+	cd "${T}" || die
+	epytest --pyargs pyamg
+}
diff --git a/dev-python/pyamg/pyamg-5.3.0.ebuild b/dev-python/pyamg/pyamg-5.3.0.ebuild
index bf08936c3035..b84ebf1c2397 100644
--- a/dev-python/pyamg/pyamg-5.3.0.ebuild
+++ b/dev-python/pyamg/pyamg-5.3.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8