3 files changed, 62 insertions, 0 deletions
diff --git a/dev-python/pyalsa/Manifest b/dev-python/pyalsa/Manifest
new file mode 100644
index 000000000000..0b3aaffcb8e2
--- /dev/null
+++ b/dev-python/pyalsa/Manifest
@@ -0,0 +1,2 @@
+DIST pyalsa-1.2.14.tar.bz2 40383 BLAKE2B dc2cf0e631b4bf954a0fd09219236067f3ca7fd0a740641b1cdec86f9bf7af6325e58ffd8b6bae3372eb6c1afdf055c2bcad1fa54cb2784edf9a18eb18923870 SHA512 8a3fec7568d9e36bdf39a048f5cfe1c7f656ea08777eac3280329afbb1c9c870136e3fd54fd334762d9942385ddfead9bc15ee86d244d8c50869b34c4cb52f7d
+DIST pyalsa-1.2.14.tar.bz2.sig 833 BLAKE2B 418d82280664f75b281d7ad07ff142a649cc076e4254d6497045b882263b36959178fb48ba33b9df6c02aa4af21bc0d17e1ef16049cb8d7e7df85a8b268f6ac0 SHA512 1653ec264d33d618197bbbe4acbe06d4dab88f7b59c9971c8ac5b8581a2e917836f1099dd4d2817abccc8089fa4f50b6741ba4a144db6438e58acf97d270b055
diff --git a/dev-python/pyalsa/metadata.xml b/dev-python/pyalsa/metadata.xml
new file mode 100644
index 000000000000..5f33304011d5
--- /dev/null
+++ b/dev-python/pyalsa/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pyalsa/pyalsa-1.2.14.ebuild b/dev-python/pyalsa/pyalsa-1.2.14.ebuild
new file mode 100644
index 000000000000..21161d821033
--- /dev/null
+++ b/dev-python/pyalsa/pyalsa-1.2.14.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/alsa.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Python bindings for ALSA library"
+HOMEPAGE="https://alsa-project.org/wiki/Main_Page"
+SRC_URI="
+	https://www.alsa-project.org/files/pub/pyalsa/${P}.tar.bz2
+	verify-sig? ( https://www.alsa-project.org/files/pub/pyalsa/${P}.tar.bz2.sig )
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm64 ~hppa ~mips ppc ppc64 ~riscv ~sparc x86"
+# Needs access to system's alsa configuration/devices
+RESTRICT="test"
+
+DEPEND="
+	media-libs/alsa-lib
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	verify-sig? ( sec-keys/openpgp-keys-alsa )
+"
+
+python_test() {
+	cd "${T}" || die
+
+	shopt -s nullglob
+	local test
+	local failed
+	for test in "${S}"/test/*.py ; do
+		${EPYTHON} "${test}" || {
+			eerror "${test} failed with ${EPYTHON}"
+			failed=1
+			break
+		}
+	done
+	shopt -u nullglob
+
+	if [[ ${failed} -eq 1 ]] ; then
+		die "${test} failed with ${EPYTHON}"
+	fi
+}