1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/portalocker/portalocker-4.3.2.ebuild b/dev-python/portalocker/portalocker-4.3.2.ebuild
new file mode 100644
index 000000000000..b3a42ce7d36d
--- /dev/null
+++ b/dev-python/portalocker/portalocker-4.3.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=uv-build
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A library for Python file locking"
+HOMEPAGE="
+	https://github.com/WoLpH/portalocker/
+	https://portalocker.readthedocs.io/
+	https://pypi.org/project/portalocker/
+"
+SRC_URI="
+	https://github.com/WoLpH/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		>=dev-python/fakeredis-2.31.0[${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-6.0.0[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.4[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{rerunfailures,timeout} )
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Disable code coverage in tests.
+	sed -i '/--cov/d' pyproject.toml || die
+}
+
+pkg_postinst() {
+	optfeature "redis support" dev-python/redis
+}