1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/pluginbase/pluginbase-1.0.0.ebuild b/dev-python/pluginbase/pluginbase-1.0.0.ebuild
new file mode 100644
index 000000000000..634f1829e08d
--- /dev/null
+++ b/dev-python/pluginbase/pluginbase-1.0.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Support library for building plugins sytems in Python"
+HOMEPAGE="https://github.com/mitsuhiko/pluginbase"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (	dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	sed -e "s/, 'sphinx.ext.intersphinx'//" \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	cd tests && PYTHONPATH=.. py.test --tb=native || die "Tests fail with ${EPYTHON}"
+}