1 files changed, 62 insertions, 0 deletions
diff --git a/dev-python/pikepdf/pikepdf-10.6.0.ebuild b/dev-python/pikepdf/pikepdf-10.6.0.ebuild
new file mode 100644
index 000000000000..c7456dc4a40d
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-10.6.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=scikit-build-core
+PYPI_VERIFY_REPO=https://github.com/pikepdf/pikepdf
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="big-endian"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+	>=app-text/qpdf-12.2.0:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/nanobind-2.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-77.0.3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		!big-endian? (
+			>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		)
+		media-libs/tiff[zlib]
+	)
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-timeout )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -e '/-n auto/d' -i pyproject.toml || die
+	# remove bundled qpdf
+	rm -rf qpdf || die
+}