3 files changed, 59 insertions, 0 deletions
diff --git a/dev-python/mss/Manifest b/dev-python/mss/Manifest
new file mode 100644
index 000000000000..9dad02df4ea2
--- /dev/null
+++ b/dev-python/mss/Manifest
@@ -0,0 +1 @@
+DIST mss-10.2.0.tar.gz 200317 BLAKE2B d644ca74474342453c5bfa98773ed90ca35539f17d5ac835053228de92ed741672ee4296d0a8100a83e3ce8ede31f18e5da5d8f078d05656028e6f25a84cd70a SHA512 80ca4ffb85cce9e551ac5c69136ae3d7bb1b836c68bae68c8ff07a9b3f707eb9ccb7e3b9b2ef19aa4f6713aa899e2b35c4a65ad869f89f9411b52c9a837e07f8
diff --git a/dev-python/mss/metadata.xml b/dev-python/mss/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/mss/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/mss/mss-10.2.0.ebuild b/dev-python/mss/mss-10.2.0.ebuild
new file mode 100644
index 000000000000..b178cb8d56c0
--- /dev/null
+++ b/dev-python/mss/mss-10.2.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="An ultra fast cross-platform multiple screenshots module in python using ctypes"
+HOMEPAGE="
+	https://github.com/BoboTiG/python-mss/
+	https://pypi.org/project/mss/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~riscv x86"
+
+BDEPEND="
+	test? (
+		dev-python/pyvirtualdisplay[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-rerunfailures )
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# upstream tests for self-build, apparently broken by setuptools
+	# issuing deprecation warnings
+	src/tests/test_setup.py
+)
+
+EPYTEST_DESELECT=(
+	# unreliable `lsof -U | grep ...` tests
+	src/tests/test_leaks.py
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+	sed -i -e '/--cov/d' pyproject.toml || die
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}