5 files changed, 128 insertions, 1 deletions
diff --git a/dev-python/libtmux/Manifest b/dev-python/libtmux/Manifest
index a87d7e7bc192..b748e7bfd086 100644
--- a/dev-python/libtmux/Manifest
+++ b/dev-python/libtmux/Manifest
@@ -4,3 +4,5 @@ DIST libtmux-0.28.0.gh.tar.gz 273309 BLAKE2B 9bc5b3068e64f09af0411f68f22cd23535b
 DIST libtmux-0.30.1.gh.tar.gz 276505 BLAKE2B 508e9b15183ecf7c3c006145fbbc9580e7180fd39b453b8a9589f644f8fddcf14144e9989c92a581c7c10a95660d9c5b9f7f5544e51e202634407c0a1914c6a2 SHA512 9ec06901f978a631b9d8085806b71912f5b582d20e917ed4409f870ec2e873095044779b1d0db2cbe0285e11a043c44cd801fa60cb2f57d9d31fb95e3015daf8
 DIST libtmux-0.30.2.gh.tar.gz 276498 BLAKE2B 13d7940d7f0f2f71819c2a5747f73fb5f0319179ec57a974461552f3de5804bc30d35c8790d8ae63bb9797b3b1aea54ab94e1f593a37cbac286b297d70d33ed0 SHA512 503dd5e7325073cc57ab9a553c3b3cf7c7cd12a506a8a59dcfd84c5902f0a1b2adab507c5b95e9abc97c9384d282bb866d8772c93b23b101d0ec8ded8f2a280d
 DIST libtmux-0.32.0.gh.tar.gz 278651 BLAKE2B c6b98925f258fb5a2c25b08ee835faf6f1189413041e592da396d0934ad712d3494c8b0985352f96fff998ecd051c0cc433377697333a88225f55392d3a1971b SHA512 daa97cdba7c07ea35c8658263a6dc3a533b6422449a31d83cb3cac4c47c2be32f3c60556ea05e5d098c090582697de0192725453d61e89ecc31f79309b1700ac
+DIST libtmux-0.33.0.gh.tar.gz 282114 BLAKE2B d1b9b1e0789c81dab17a1d0be3708f34388952b2ea583f0efac280503365dba033d0c181f6ae1eb247ea2252288d47d4ab5b2a227077a5653e3e842bf8f01fa7 SHA512 30641730c57b68fc887513618596f951dd60ddf97c0bc6acaf1c489abbfc91ee1439ab158b9453df382fcb8163c0b7812de20955909950c173042103707c3705
+DIST libtmux-0.34.0.gh.tar.gz 282504 BLAKE2B 9ff5d3124c1fc26fa7cc825b3cd145126362a88da2ab691c711149772e293f7ea30277cc842d7d5347d7529009ae5d2c30926d724f5ddc957cdcb395df9fa06b SHA512 6431cd3fca0f51a3dfa4e5a10031f11cc3520a20a904196b2d03d86b71845082564bde85cb2be4f5fc30ef762af5dbac16c131cbc548e2e3a827d8892f1202b3
diff --git a/dev-python/libtmux/libtmux-0.30.2.ebuild b/dev-python/libtmux/libtmux-0.30.2.ebuild
index ef94f2a0f37e..8e9bc62cd8e5 100644
--- a/dev-python/libtmux/libtmux-0.30.2.ebuild
+++ b/dev-python/libtmux/libtmux-0.30.2.ebuild
@@ -53,5 +53,8 @@ python_test() {
 	local -a EPYTEST_DESELECT=(
 		libtmux/pane.py::libtmux.pane.Pane.send_keys
 	)
+	# tests/test_window.py::test_fresh_window_data fails if TMUX_PANE is set
+	# https://bugs.gentoo.org/927158
+	local -x TMUX_PANE=
 	epytest
 }
diff --git a/dev-python/libtmux/libtmux-0.32.0.ebuild b/dev-python/libtmux/libtmux-0.32.0.ebuild
index ef94f2a0f37e..5332eae240aa 100644
--- a/dev-python/libtmux/libtmux-0.32.0.ebuild
+++ b/dev-python/libtmux/libtmux-0.32.0.ebuild
@@ -53,5 +53,10 @@ python_test() {
 	local -a EPYTEST_DESELECT=(
 		libtmux/pane.py::libtmux.pane.Pane.send_keys
 	)
-	epytest
+	# tests/test_window.py::test_fresh_window_data fails if TMUX_PANE is set
+	# https://bugs.gentoo.org/927158
+	local -x TMUX_PANE=
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=libtmux.pytest_plugin
+	epytest -p pytest_mock -p rerunfailures
 }
diff --git a/dev-python/libtmux/libtmux-0.33.0.ebuild b/dev-python/libtmux/libtmux-0.33.0.ebuild
new file mode 100644
index 000000000000..6bc81c7a99eb
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.33.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Typed library that provides an ORM wrapper for tmux, a terminal multiplexer"
+HOMEPAGE="
+	https://libtmux.git-pull.com/
+	https://github.com/tmux-python/libtmux/
+	https://pypi.org/project/libtmux/
+"
+SRC_URI="
+	https://github.com/tmux-python/libtmux/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# tests/test_window.py::test_fresh_window_data fails if TMUX_PANE is set
+	# https://bugs.gentoo.org/927158
+	local -x TMUX_PANE=
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=libtmux.pytest_plugin
+	epytest -o addopts= -p pytest_mock -p rerunfailures tests
+}
diff --git a/dev-python/libtmux/libtmux-0.34.0.ebuild b/dev-python/libtmux/libtmux-0.34.0.ebuild
new file mode 100644
index 000000000000..4d09659b6750
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.34.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Typed library that provides an ORM wrapper for tmux, a terminal multiplexer"
+HOMEPAGE="
+	https://libtmux.git-pull.com/
+	https://github.com/tmux-python/libtmux/
+	https://pypi.org/project/libtmux/
+"
+SRC_URI="
+	https://github.com/tmux-python/libtmux/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# tests/test_window.py::test_fresh_window_data fails if TMUX_PANE is set
+	# https://bugs.gentoo.org/927158
+	local -x TMUX_PANE=
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=libtmux.pytest_plugin
+
+	local EPYTEST_DESELECT=(
+		# flaky tests
+		tests/legacy_api/test_test.py::test_function_times_out
+		tests/legacy_api/test_test.py::test_function_times_out_no_raise
+		tests/legacy_api/test_test.py::test_function_times_out_no_raise_assert
+	)
+	epytest -o addopts= -p pytest_mock -p rerunfailures tests
+}