3 files changed, 92 insertions, 0 deletions
diff --git a/dev-python/jsonpickle/Manifest b/dev-python/jsonpickle/Manifest
new file mode 100644
index 000000000000..f5c840dd4ee5
--- /dev/null
+++ b/dev-python/jsonpickle/Manifest
@@ -0,0 +1 @@
+DIST jsonpickle-4.1.1.gh.tar.gz 309768 BLAKE2B 06711ba9123ae2d5e453e2fa277629131c62518dbb3bbd48e0f589e6fc02aea7094d2ce7d7a8dbbb2430077f380c14e26c318c2f669d37610897c8ebdf922d58 SHA512 13894e2e5ed258f8d16e27fd2e7ca5d0d38ae91552675c121b3516e4d22c2732b9a9a0656e06e648ae115e523a0f1ae82d756fbf504a884abe9ea7ad6bbccc5a
diff --git a/dev-python/jsonpickle/jsonpickle-4.1.1.ebuild b/dev-python/jsonpickle/jsonpickle-4.1.1.ebuild
new file mode 100644
index 000000000000..8d0a23bd21f1
--- /dev/null
+++ b/dev-python/jsonpickle/jsonpickle-4.1.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_FULLY_TESTED=( python3_{12..13} )
+PYTHON_COMPAT=( python3_{13..14} )
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for serializing any arbitrary object graph into JSON"
+HOMEPAGE="
+	https://github.com/jsonpickle/jsonpickle/
+	https://pypi.org/project/jsonpickle/
+"
+SRC_URI="
+	https://github.com/jsonpickle/jsonpickle/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~riscv x86"
+IUSE="test-full"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/feedparser[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+		test-full? (
+			$(python_gen_cond_dep '
+				dev-python/gmpy2[${PYTHON_USEDEP}]
+				dev-python/pandas[${PYTHON_USEDEP}]
+			' "${PYTHON_FULLY_TESTED[@]}")
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# unpackaged bson dependency
+		tests/bson_test.py
+	)
+
+	if ! use test-full || ! has_version "dev-python/gmpy2[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=( jsonpickle/ext/gmpy.py )
+	fi
+	if ! use test-full || ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=( jsonpickle/ext/pandas.py )
+	fi
+
+	epytest tests
+}
+
+pkg_postinst() {
+	# Unpackaged optional backends: yajl, demjson
+	optfeature "encoding numpy-based data" dev-python/numpy
+	optfeature "encoding pandas objects" dev-python/pandas
+	optfeature "fast JSON backend" dev-python/simplejson
+}
diff --git a/dev-python/jsonpickle/metadata.xml b/dev-python/jsonpickle/metadata.xml
new file mode 100644
index 000000000000..3f00dee7f622
--- /dev/null
+++ b/dev-python/jsonpickle/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <use>
+    <flag name="test-full">
+      Run test suite in full via additional (large) test
+      dependencies, like dev-python/pandas.
+    </flag>
+  </use>
+  <upstream>
+    <remote-id type="cpe">cpe:/a:jsonpickle_project:jsonpickle</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>