summaryrefslogtreecommitdiff
path: root/dev-python/irc
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/irc')
-rw-r--r--dev-python/irc/Manifest2
-rw-r--r--dev-python/irc/irc-16.3.ebuild66
-rw-r--r--dev-python/irc/irc-18.0.0-r1.ebuild58
-rw-r--r--dev-python/irc/metadata.xml24
4 files changed, 150 insertions, 0 deletions
diff --git a/dev-python/irc/Manifest b/dev-python/irc/Manifest
new file mode 100644
index 000000000000..8fc3c9f09bb6
--- /dev/null
+++ b/dev-python/irc/Manifest
@@ -0,0 +1,2 @@
+DIST irc-16.3.tar.gz 87067 BLAKE2B 61d8b9cc20390a3eb918e5593a167b28f37154ee05cb4d7a72f8901509d3345e8d6bee9c17b66aa6c71fad4608a9f98eb3848190f82eac7db6f2013227979c25 SHA512 84b5a56a441cdf22396c10b81c115cb2e297ac082785e9baf0bc73d655034be1ff3f553d44412f066ab4b74530faddb66a9cc2f511a332e87fe49af0b6e68e5b
+DIST irc-18.0.0.tar.gz 91529 BLAKE2B 91e7f9fe38b46f836eb902c8ce4ca04706e673a8a9372c743e9b6be3b400e4d84a0d841b72e2b8444e055a69d37b22d48fcf33c7bd51375dbf0dd4a06b3ed5dd SHA512 a424f1261a09246dd2cfd0b717d4fd9bbeab9754d1f480c870c2e131354db85268bd010ec6b7cf2c59a0c32057bb290ef3ffdcb30cca8c0d833e1497bc89f58e
diff --git a/dev-python/irc/irc-16.3.ebuild b/dev-python/irc/irc-16.3.ebuild
new file mode 100644
index 000000000000..f917dce5e7c4
--- /dev/null
+++ b/dev-python/irc/irc-16.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/jaraco-functools-1.5[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+ >=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+ dev-python/jaraco-collections[${PYTHON_USEDEP}]
+ dev-python/jaraco-logging[${PYTHON_USEDEP}]
+ dev-python/jaraco-stream[${PYTHON_USEDEP}]
+ dev-python/jaraco-text[${PYTHON_USEDEP}]
+ dev-python/more-itertools[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ >=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+ doc? (
+ >=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+ >=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ )
+ test? (
+ ${RDEPEND}
+ dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+ >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+ )
+"
+
+python_compile_all() {
+ if use doc; then
+ cd docs || die
+ sphinx-build . _build/html || die
+ HTML_DOCS=( docs/_build/html/. )
+ fi
+}
+
+python_test() {
+ # Override pytest options to skip flake8
+ pytest -vv --override-ini="addopts=--doctest-modules" \
+ || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/scripts"
+ dodoc -r scripts
+ fi
+ distutils-r1_python_install_all
+}
diff --git a/dev-python/irc/irc-18.0.0-r1.ebuild b/dev-python/irc/irc-18.0.0-r1.ebuild
new file mode 100644
index 000000000000..bc2ceafe82d0
--- /dev/null
+++ b/dev-python/irc/irc-18.0.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ $(python_gen_cond_dep 'dev-python/importlib_metadata[${PYTHON_USEDEP}]' python3_{6,7})
+ dev-python/jaraco-collections[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+ dev-python/jaraco-logging[${PYTHON_USEDEP}]
+ dev-python/jaraco-stream[${PYTHON_USEDEP}]
+ dev-python/jaraco-text[${PYTHON_USEDEP}]
+ dev-python/more-itertools[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+ >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs '>=dev-python/jaraco-packaging-3.2' \
+ '>=dev-python/rst-linker-1.9'
+
+python_test() {
+ # Override pytest options to skip flake8
+ # Skip a test that fails with 3.8 until it is fixed
+ # https://github.com/jaraco/irc/issues/165
+ pytest -vv --override-ini="addopts=--doctest-modules" \
+ --deselect irc/tests/test_client_aio.py::test_privmsg_sends_msg \
+ || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/scripts"
+ dodoc -r scripts
+ fi
+ distutils-r1_python_install_all
+}
diff --git a/dev-python/irc/metadata.xml b/dev-python/irc/metadata.xml
new file mode 100644
index 000000000000..5fff3d4526d5
--- /dev/null
+++ b/dev-python/irc/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>sbraz@gentoo.org</email>
+ <name>Louis Sautier</name>
+ </maintainer>
+ <maintainer type="project">
+ <email>python@gentoo.org</email>
+ <name>Python</name>
+ </maintainer>
+ <longdescription>
+ This project includes an event-driven IRC client framework written in Python,
+ as well as an object-oriented wrapper class and some example programs.
+ </longdescription>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">irc</remote-id>
+ <remote-id type="github">jaraco/irc</remote-id>
+ <bugs-to>https://github.com/jaraco/irc/issues</bugs-to>
+ <changelog>https://github.com/jaraco/irc/blob/master/CHANGES.rst</changelog>
+ </upstream>
+ <origin>gentoo-staging</origin>
+</pkgmetadata>
generated by cgit v1.3.1 (git 2.54.0) at 2026-06-02 13:28:41 +0000