3 files changed, 65 insertions, 0 deletions
diff --git a/dev-python/immutables/Manifest b/dev-python/immutables/Manifest
new file mode 100644
index 000000000000..942e39726aec
--- /dev/null
+++ b/dev-python/immutables/Manifest
@@ -0,0 +1 @@
+DIST immutables-0.21.gh.tar.gz 88188 BLAKE2B be5f5e247f16549b1ccf2fa4a95b81818795d04a0ed934509dc3dcac985be4779ea3c2634cd9e8b57321d58ebf63ce828df08f39f19819e6b537ea3195ae87e3 SHA512 ffd754cd5f13f0d961ec05b1c19df4f9a25c0804a402d0dee91e163531eb9f30b50d8abb1252df775cb83922c69b02baa51bef5d6aa17d80fca57442b93d5e94
diff --git a/dev-python/immutables/immutables-0.21.ebuild b/dev-python/immutables/immutables-0.21.ebuild
new file mode 100644
index 000000000000..efdff2f58fd2
--- /dev/null
+++ b/dev-python/immutables/immutables-0.21.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2019-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A high-performance immutable mapping type for Python"
+HOMEPAGE="
+	https://github.com/MagicStack/immutables/
+	https://pypi.org/project/immutables/
+"
+SRC_URI="
+	https://github.com/MagicStack/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+IUSE="+native-extensions"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/mypy/d' tests/conftest.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	# upstream controls NDEBUG explicitly
+	use debug && local -x DEBUG_IMMUTABLES=1
+	local -x IMMUTABLES_EXT=$(usex native-extensions 1 0)
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		tests/test_mypy.py
+	)
+
+	rm -rf immutables || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/immutables/metadata.xml b/dev-python/immutables/metadata.xml
new file mode 100644
index 000000000000..cb20198656b1
--- /dev/null
+++ b/dev-python/immutables/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+  </maintainer>
+  <use>
+    <flag name="native-extensions">
+			Compiles native "C" extensions (speedups, instead of using Python
+			fallback code).
+		</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>