1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/geoip-python/geoip-python-1.3.2-r1.ebuild b/dev-python/geoip-python/geoip-python-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..f89ae7f8f23e
--- /dev/null
+++ b/dev-python/geoip-python/geoip-python-1.3.2-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="geoip-api-python"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for GeoIP"
+HOMEPAGE="https://github.com/maxmind/geoip-api-python"
+SRC_URI="https://github.com/maxmind/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~ia64 ~ppc ~sparc x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-libs/geoip-1.4.8"
+DEPEND="
+	${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( README.rst ChangeLog.md )
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}