1 files changed, 62 insertions, 0 deletions
diff --git a/dev-python/fonttools/fonttools-4.63.0.ebuild b/dev-python/fonttools/fonttools-4.63.0.ebuild
new file mode 100644
index 000000000000..4ca323d0b781
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.63.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+	https://github.com/fonttools/fonttools/
+	https://pypi.org/project/fonttools/
+"
+SRC_URI="
+	https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/munkres[${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-rerunfailures )
+# woff2 tests are extremely flaky
+EPYTEST_RERUNS=20
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x FONTTOOLS_WITH_CYTHON=$(usex native-extensions)
+	[[ ${EPYTHON} == pypy3 ]] && FONTTOOLS_WITH_CYTHON=0
+	distutils-r1_python_compile
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# nonfatal for virtx
+	nonfatal epytest Tests fontTools ||
+		die -n "Tests failed with ${EPYTHON}"
+}