1 files changed, 52 insertions, 0 deletions
diff --git a/dev-python/flask-debug/flask-debug-0.4.3.ebuild b/dev-python/flask-debug/flask-debug-0.4.3.ebuild
new file mode 100644
index 000000000000..8a4e915c7738
--- /dev/null
+++ b/dev-python/flask-debug/flask-debug-0.4.3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy3 python3_{6,7} )
+
+inherit distutils-r1
+
+MY_PN="Flask-Debug"
+DESCRIPTION="Flask extension that displays various debugging insights during development"
+HOMEPAGE="https://github.com/mbr/Flask-Debug"
+# PyPI tarballs don't include tests
+# https://github.com/mbr/Flask-Debug/pull/2
+SRC_URI="https://github.com/mbr/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/inflection[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	pytest -vv || die "Tests failed with ${EPYTHON}"
+}